[gentoo-commits] repo/gentoo:master commit in: dev-vcs/git-cola/

[Tiziano Müller]

commit:     5730e72e97baac827442e8e37820257372d2ae37
Author:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 20 07:35:08 2018 +0000
Commit:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
CommitDate: Tue Nov 20 07:42:43 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5730e72e

dev-vcs/git-cola: version bump to 3.2

Closes: https://bugs.gentoo.org/655908
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Tiziano Müller <dev-zero <AT> gentoo.org>

 dev-vcs/git-cola/Manifest            |  1 +
 dev-vcs/git-cola/git-cola-3.2.ebuild | 98 ++++++++++++++++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/dev-vcs/git-cola/Manifest b/dev-vcs/git-cola/Manifest
index 64328eade56..6318f76f93f 100644
--- a/dev-vcs/git-cola/Manifest
+++ b/dev-vcs/git-cola/Manifest
@@ -1 +1,2 @@
 DIST git-cola-2.11.tar.gz 1179769 BLAKE2B db2926b8137b2bb11cc9698b37156d8b0c8f72068061d7d1598b2e3237e44764c2914923103aaaa704babe26cf7a7c16bbe28a61770d98954f776b8ce955658a SHA512 99b865d7a49dcb041e54811141d242386642b5ed6fc12fa7a03431eb9b905cb88d88c4892dc432dd59e8ae3c85f20cc40f4bfb9b6ff002f4e5a4cfc0bdc4c72c
+DIST git-cola-3.2.tar.gz 1208723 BLAKE2B e0375502c7b760a35217c48708e34ba061934f968e6720c3560603b5a76c9474a3a8426f2120ee853a9ac475fc9cbc33ee6ee9a946336e1f28a89d541785c535 SHA512 ca171549dad692088e337efad6f480103a41a1a94f57ae66c15fab3d69e3b18ecc28ac1178886fedd6d969f783e8d5feb4922539c1739ce52c0c0ac59dc941ee

diff --git a/dev-vcs/git-cola/git-cola-3.2.ebuild b/dev-vcs/git-cola/git-cola-3.2.ebuild
new file mode 100644
index 00000000000..02897b8b6a9
--- /dev/null
+++ b/dev-vcs/git-cola/git-cola-3.2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+DISTUTILS_SINGLE_IMPL=true
+
+inherit distutils-r1 readme.gentoo-r1 virtualx
+
+DESCRIPTION="The highly caffeinated git GUI"
+HOMEPAGE="https://git-cola.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="dev-python/QtPy[gui,${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-vcs/git"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		python_targets_python2_7? ( dev-python/sphinxtogithub[$(python_gen_usedep 'python2*')] )
+		)
+	test? (
+		${VIRTUALX_DEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		)"
+
+python_prepare_all() {
+	# make sure that tests also use the system provided QtPy
+	rm -r qtpy || die
+
+	rm share/git-cola/bin/*askpass* || die
+
+	# don't install docs into wrong location
+	sed -i -e '/doc/d' setup.py || die
+
+	# fix doc directory reference
+	sed -i \
+		-e "s/'doc', 'git-cola'/'doc', '${PF}'/" \
+		cola/resources.py || die
+
+	# fix ssh-askpass directory reference
+	sed -i -e 's/resources\.share/resources\.prefix/' cola/app.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	mydistutilsargs=( --no-vendor-libs )
+}
+
+python_compile_all() {
+	cd share/doc/${PN}/ || die
+	if use doc ; then
+		emake all
+	else
+		sed \
+			-e '/^install:/s:install-html::g' \
+			-e '/^install:/s:install-man::g' \
+			-i Makefile || die
+	fi
+}
+
+python_test() {
+	PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="en_US.utf8" \
+	virtx nosetests --verbose --with-id --with-doctest \
+		--exclude=sphinxtogithub
+}
+
+src_install() {
+	distutils-r1_src_install
+}
+
+python_install_all() {
+	cd share/doc/${PN}/ || die
+	emake \
+		DESTDIR="${D}" \
+		docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		prefix="${EPREFIX}/usr" \
+		install
+
+	python_fix_shebang "${ED}/usr/share/git-cola/bin/git-xbase" "${ED}"/usr/bin/git-cola
+	python_optimize "${ED}/usr/share/git-cola/lib/cola"
+
+	use doc || HTML_DOCS=( "${FILESDIR}"/index.html )
+
+	distutils-r1_python_install_all
+	readme.gentoo_create_doc
+}