[gentoo-commits] gentoo-x86 commit in sys-process/at: at-3.1.13-r1.ebuild ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     12/01/10 02:19:12

  Modified:             ChangeLog
  Added:                at-3.1.13-r1.ebuild
  Log:
  Bug #343537: refactor pam.d/atd to use system-services stack.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.32                 sys-process/at/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-process/at/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -p -w -b -B -u -u -r1.31 -r1.32
--- ChangeLog	31 Oct 2011 01:17:19 -0000	1.31
+++ ChangeLog	10 Jan 2012 02:19:12 -0000	1.32
@@ -1,6 +1,12 @@
 # ChangeLog for sys-process/at
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-process/at/ChangeLog,v 1.31 2011/10/31 01:17:19 polynomial-c Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/at/ChangeLog,v 1.32 2012/01/10 02:19:12 robbat2 Exp $
+
+*at-3.1.13-r1 (10 Jan 2012)
+
+  10 Jan 2012; Robin H. Johnson <robbat2@g.o> +at-3.1.13-r1.ebuild,
+  +files/at.pamd-3.1.13-r1:
+  Bug #343537: refactor pam.d/atd to use system-services stack.
 
   31 Oct 2011; Lars Wendler <polynomial-c@g.o> at-3.1.10.2-r1.ebuild,
   at-3.1.10.2-r2.ebuild, at-3.1.13.ebuild:



1.1                  sys-process/at/at-3.1.13-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/at-3.1.13-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/at-3.1.13-r1.ebuild?rev=1.1&content-type=text/plain

Index: at-3.1.13-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/at/at-3.1.13-r1.ebuild,v 1.1 2012/01/10 02:19:12 robbat2 Exp $

EAPI=4

inherit autotools eutils flag-o-matic pam

DESCRIPTION="Queues jobs for later execution"
HOMEPAGE="http://packages.qa.debian.org/a/at.html"
SRC_URI="mirror://debian/pool/main/a/at/${PN}_${PV}.orig.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="pam"

DEPEND="virtual/mta
	>=sys-devel/autoconf-2.64
	>=sys-devel/flex-2.5.4a
	pam? ( virtual/pam )"
RDEPEND="virtual/mta
	virtual/logger"

pkg_setup() {
	enewgroup at 25
	enewuser at 25 -1 /var/spool/at/atjobs at
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.1.8-more-deny.patch
	epatch "${FILESDIR}"/${PN}-3.1.13-Makefile.patch
	# fix parallel make issues, bug #244884
	epatch "${FILESDIR}"/${PN}-3.1.10.2-Makefile.in-parallel-make-fix.patch
	epatch "${FILESDIR}"/${P}-configure.in-fix-PAM-automagick-dep.patch

	eautoconf
}

src_configure() {
	use pam || my_conf="--without-pam"
	econf \
		--sysconfdir=/etc/at \
		--with-jobdir=/var/spool/at/atjobs \
		--with-atspool=/var/spool/at/atspool \
		--with-etcdir=/etc/at \
		--with-daemon_username=at \
		--with-daemon_groupname=at \
		${my_conf}
}

src_install() {
	make install IROOT="${D}" || die

	newinitd "${FILESDIR}"/atd.rc6 atd
	newconfd "${FILESDIR}"/atd.confd atd
	newpamd "${FILESDIR}"/at.pamd-3.1.13-r1 atd

	# Preserve existing .SEQ files (bug #386625)
	local seq_file="${ROOT}/var/spool/at/atjobs/.SEQ"
	if [ -f "${seq_file}" ] ; then
		einfo "Preserving existing .SEQ file (bug #386625)."
		cp -p "${seq_file}" "${D}"/var/spool/at/atjobs/ || die
	fi
}

pkg_postinst() {
	einfo "Forcing correct permissions on /var/spool/at"
	chown at:at "${ROOT}/var/spool/at/atjobs"
	chmod 1770  "${ROOT}/var/spool/at/atjobs"
	chown at:at "${ROOT}/var/spool/at/atjobs/.SEQ"
	chmod 0600  "${ROOT}/var/spool/at/atjobs/.SEQ"
	chown at:at "${ROOT}/var/spool/at/atspool"
	chmod 1770  "${ROOT}/var/spool/at/atspool"
}