[gentoo-commits] gentoo-x86 commit in sys-devel/gcc: ChangeLog gcc-4.4.3.ebuild

[Mike Frysinger (vapier)]

vapier      10/02/08 12:58:15

  Modified:             ChangeLog
  Added:                gcc-4.4.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.742                sys-devel/gcc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/ChangeLog?rev=1.742&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/ChangeLog?rev=1.742&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/ChangeLog?r1=1.741&r2=1.742

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/gcc/ChangeLog,v
retrieving revision 1.741
retrieving revision 1.742
diff -u -r1.741 -r1.742
--- ChangeLog	9 Jan 2010 12:58:57 -0000	1.741
+++ ChangeLog	8 Feb 2010 12:58:14 -0000	1.742
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/gcc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/ChangeLog,v 1.741 2010/01/09 12:58:57 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/ChangeLog,v 1.742 2010/02/08 12:58:14 vapier Exp $
+
+*gcc-4.4.3 (08 Feb 2010)
+
+  08 Feb 2010; Mike Frysinger <vapier@g.o> +gcc-4.4.3.ebuild:
+  Version bump.
 
   09 Jan 2010; Ulrich Mueller <ulm@g.o> gcc-4.0.4.ebuild,
   gcc-4.1.2.ebuild, gcc-4.2.4-r1.ebuild, gcc-4.3.2-r3.ebuild,



1.1                  sys-devel/gcc/gcc-4.4.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/gcc-4.4.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/gcc-4.4.3.ebuild?rev=1.1&content-type=text/plain

Index: gcc-4.4.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/gcc-4.4.3.ebuild,v 1.1 2010/02/08 12:58:14 vapier Exp $

PATCH_VER="1.0"
UCLIBC_VER="1.0"

ETYPE="gcc-compiler"

# Hardened gcc 4 stuff
#PIE_VER="10.1.5"
#SPECS_VER="0.9.4"

# arch/libc configurations known to be stable or untested with {PIE,SSP,FORTIFY}-by-default
#PIE_GLIBC_STABLE="x86 amd64 ~ppc ~ppc64 ~arm ~sparc"
#PIE_UCLIBC_STABLE="x86 arm"
#SSP_STABLE="amd64 x86 ppc ppc64 ~arm ~sparc"
#SSP_UCLIBC_STABLE=""

# whether we should split out specs files for multiple {PIE,SSP}-by-default
# and vanilla configurations.
SPLIT_SPECS=no #${SPLIT_SPECS-true} hard disable until #106690 is fixed

inherit toolchain

DESCRIPTION="The GNU Compiler Collection.  Includes C/C++, java compilers, pie+ssp extensions, Haj Ten Brugge runtime bounds checking"

LICENSE="GPL-3 LGPL-3 || ( GPL-3 libgcc libstdc++ gcc-runtime-library-exception-3.1 ) FDL-1.2"
KEYWORDS="~alpha ~amd64 ~arm -hppa ~ia64 ~mips ~ppc ~ppc64 -sparc ~x86 ~x86-fbsd"

RDEPEND=">=sys-libs/zlib-1.1.4
	>=sys-devel/gcc-config-1.4
	virtual/libiconv
	>=dev-libs/gmp-4.2.1
	>=dev-libs/mpfr-2.3.2
	graphite? (
		>=dev-libs/ppl-0.10
		>=dev-libs/cloog-ppl-0.15.4
	)
	!build? (
		gcj? (
			gtk? (
				x11-libs/libXt
				x11-libs/libX11
				x11-libs/libXtst
				x11-proto/xproto
				x11-proto/xextproto
				>=x11-libs/gtk+-2.2
				x11-libs/pango
			)
			>=media-libs/libart_lgpl-2.1
			app-arch/zip
			app-arch/unzip
		)
		>=sys-libs/ncurses-5.2-r2
		nls? ( sys-devel/gettext )
	)"
DEPEND="${RDEPEND}
	test? ( >=dev-util/dejagnu-1.4.4 >=sys-devel/autogen-5.5.4 )
	>=sys-apps/texinfo-4.8
	>=sys-devel/bison-1.875
	elibc_glibc? ( >=sys-libs/glibc-2.8 )
	amd64? ( multilib? ( gcj? ( app-emulation/emul-linux-x86-xlibs ) ) )
	ppc? ( >=${CATEGORY}/binutils-2.17 )
	ppc64? ( >=${CATEGORY}/binutils-2.17 )
	>=${CATEGORY}/binutils-2.15.94"
PDEPEND=">=sys-devel/gcc-config-1.4"
if [[ ${CATEGORY} != cross-* ]] ; then
	PDEPEND="${PDEPEND} elibc_glibc? ( >=sys-libs/glibc-2.8 )"
fi

src_unpack() {
	gcc_src_unpack

	use vanilla && return 0

	sed -i 's/use_fixproto=yes/:/' gcc/config.gcc #PR33200

	[[ ${CHOST} == ${CTARGET} ]] && epatch "${FILESDIR}"/gcc-spec-env.patch

	[[ ${CTARGET} == *-softfloat-* ]] && epatch "${FILESDIR}"/4.4.0/gcc-4.4.0-softfloat.patch
}