[gentoo-commits] repo/gentoo:master commit in: www-client/opera/

[Jeroen Roovers]

commit:     0b474a529c1812474b190b649b58b3b4a45b9d93
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 29 19:33:21 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Wed Sep 30 02:47:08 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0b474a52

www-client/opera: Version 71.0.3770.198

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 www-client/opera/Manifest                   |  1 +
 www-client/opera/opera-71.0.3770.198.ebuild | 98 +++++++++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index fdaed05aafe..6a45208055a 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1 +1,2 @@
 DIST opera-stable_71.0.3770.171_amd64.deb 67804340 BLAKE2B 973c0dc2ad27e1cf5b9e17dac7ff0f5eb0cc821c909467857b505d17bc1c8d7b29396ee4ef17e3ea01b0d48a9ef99fd756c928deeecc31dda595d22fd057751a SHA512 e6782456b74546227ca6bf80ce32882cde6e4c6f8eab4b3930069e4c2112065b79648ed0f0847cc6fcb1ec6f1dd5a7e37144c3382bb294237dd24f047906bd20
+DIST opera-stable_71.0.3770.198_amd64.deb 67830756 BLAKE2B ac0feda2b658bdd3447a17b5e63d29d86ae3ddcd8d762fe8756d4151a7ef152f97623269198c509562bde3a6e105067fed5e00a8345c65af914a1667d9df90a5 SHA512 9eea20f3416b04559270a41c6e35bc6e018de6f4b98673780bb5dd66160239e5a9edd37e364549a68bc2cc26c7db1a4a13c77d5c0f55896ce385cc9ffef15716

diff --git a/www-client/opera/opera-71.0.3770.198.ebuild b/www-client/opera/opera-71.0.3770.198.ebuild
new file mode 100644
index 00000000000..4a76841018c
--- /dev/null
+++ b/www-client/opera/opera-71.0.3770.198.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+
+"
+inherit chromium-2 multilib unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/desktop/${PV}/linux/${PN}-stable_${PV}_amd64.deb"
+"
+done
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	default
+
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}-stable/copyright || die
+	mv usr/share/doc/${PN}-stable usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	pushd "${OPERA_HOME}"/localization > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	rm "${OPERA_HOME}"/${PN}_autoupdate || die
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /"${OPERA_HOME}"/opera_sandbox
+}