[gentoo-commits] gentoo-x86 commit in net-fs/autofs: ChangeLog autofs-5.0.9.ebuild

[Yixun Lan (dlan)]

dlan        14/03/28 22:03:48

  Modified:             ChangeLog
  Added:                autofs-5.0.9.ebuild
  Log:
  bump to 5.0.9
  
  (Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 0xAABEFD55)

Revision  Changes    Path
1.174                net-fs/autofs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/ChangeLog?rev=1.174&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/ChangeLog?rev=1.174&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/ChangeLog?r1=1.173&r2=1.174

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v
retrieving revision 1.173
retrieving revision 1.174
diff -u -r1.173 -r1.174
--- ChangeLog	17 Jan 2014 07:17:41 -0000	1.173
+++ ChangeLog	28 Mar 2014 22:03:48 -0000	1.174
@@ -1,6 +1,11 @@
 # ChangeLog for net-fs/autofs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v 1.173 2014/01/17 07:17:41 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v 1.174 2014/03/28 22:03:48 dlan Exp $
+
+*autofs-5.0.9 (28 Mar 2014)
+
+  28 Mar 2014; Yixun Lan <dlan@g.o> +autofs-5.0.9.ebuild:
+  bump to 5.0.9
 
   17 Jan 2014; Yixun Lan <dlan@g.o> metadata.xml:
   update maintainer email



1.1                  net-fs/autofs/autofs-5.0.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/autofs-5.0.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/autofs-5.0.9.ebuild?rev=1.1&content-type=text/plain

Index: autofs-5.0.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/autofs-5.0.9.ebuild,v 1.1 2014/03/28 22:03:48 dlan Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=true
AUTOTOOLS_IN_SOURCE_BUILD=true

inherit autotools-utils linux-info multilib systemd toolchain-funcs

PATCH_VER=
[[ -n ${PATCH_VER} ]] && \
	PATCHSET_URI="http://dev.gentoo.org/~jlec/distfiles/${P}-patches-${PATCH_VER}.tar.lzma"

DESCRIPTION="Kernel based automounter"
HOMEPAGE="http://www.linux-consulting.com/Amd_AutoFS/autofs.html"
SRC_URI="
	mirror://kernel/linux/daemons/${PN}/v5/${P}.tar.xz
	${PATCHSET_URI}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="-dmalloc hesiod ldap libtirpc mount-locking sasl"

# USE="sasl" adds SASL support to the LDAP module which will not be build. If
# SASL support should be available, please add "ldap" to the USE flags.
REQUIRED_USE="sasl? ( ldap )"

# currently, sasl code assumes the presence of kerberosV
RDEPEND=">=sys-apps/util-linux-2.20
	dmalloc? ( dev-libs/dmalloc[threads] )
	hesiod? ( net-dns/hesiod )
	ldap? ( >=net-nds/openldap-2.0
		sasl? (
			dev-libs/cyrus-sasl
			dev-libs/libxml2
			virtual/krb5
		)
	)
	libtirpc? ( net-libs/libtirpc )"

DEPEND="${RDEPEND}
	sys-devel/flex
	virtual/yacc"

CONFIG_CHECK="~AUTOFS4_FS"

src_prepare() {
	# Upstream's patchset
	if [[ -n ${PATCH_VER} ]]; then
		EPATCH_SUFFIX="patch" \
			epatch "${WORKDIR}"/patches
	fi

	sed -i -e "s:/usr/bin/kill:/bin/kill:" samples/autofs.service.in || die #bug #479492
	autotools-utils_src_prepare
}

src_configure() {
	# bug #483716
	tc-export AR
	# --with-confdir is for bug #361481
	# --with-mapdir is for bug #385113
	local myeconfargs=(
		--with-confdir=/etc/conf.d
		--with-mapdir=/etc/autofs
		$(use_with dmalloc)
		$(use_with ldap openldap)
		$(use_with libtirpc)
		$(use_with sasl)
		$(use_with hesiod)
		$(use_enable mount-locking)
		--disable-ext-env
		--enable-sloppy-mount # bug #453778
		--enable-force-shutdown
		--enable-ignore-busy
		--with-systemd="$(systemd_get_unitdir)" #bug #479492
		RANLIB="$(type -P $(tc-getRANLIB))" # bug #483716
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile DONTSTRIP=1
}

src_install() {
	autotools-utils_src_install

	if kernel_is -lt 2 6 30; then
		# kernel patches
		docinto patches
		dodoc patches/${PN}4-2.6.??{,.?{,?}}-v5-update-????????.patch
	fi
	newinitd "${FILESDIR}"/autofs5.initd autofs
	insinto etc/autofs
	newins "${FILESDIR}"/autofs5-auto.master auto.master
}

pkg_postinst() {
	if kernel_is -lt 2 6 30; then
		elog "This version of ${PN} requires a kernel with autofs4 supporting"
		elog "protocol version 5.00. Patches for kernels older than 2.6.30 have"
		elog "been installed into"
		elog "${EROOT}usr/share/doc/${P}/patches."
		elog "For further instructions how to patch the kernel, please refer to"
		elog "${EROOT}usr/share/doc/${P}/INSTALL."
		elog
	fi
	elog "If you plan on using autofs for automounting remote NFS mounts,"
	elog "please check that both portmap (or rpcbind) and rpc.statd/lockd"
	elog "are running."
}