[gentoo-commits] gentoo-x86 commit in net-dialup/minicom: minicom-2.7.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    14/01/01 19:54:42

  Modified:             ChangeLog
  Added:                minicom-2.7.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.102                net-dialup/minicom/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/minicom/ChangeLog?rev=1.102&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/minicom/ChangeLog?rev=1.102&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/minicom/ChangeLog?r1=1.101&r2=1.102

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dialup/minicom/ChangeLog,v
retrieving revision 1.101
retrieving revision 1.102
diff -u -r1.101 -r1.102
--- ChangeLog	30 Oct 2013 08:43:27 -0000	1.101
+++ ChangeLog	1 Jan 2014 19:54:42 -0000	1.102
@@ -1,6 +1,11 @@
 # ChangeLog for net-dialup/minicom
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dialup/minicom/ChangeLog,v 1.101 2013/10/30 08:43:27 pinkbyte Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-dialup/minicom/ChangeLog,v 1.102 2014/01/01 19:54:42 radhermit Exp $
+
+*minicom-2.7 (01 Jan 2014)
+
+  01 Jan 2014; Tim Harder <radhermit@g.o> +minicom-2.7.ebuild:
+  Version bump.
 
 *minicom-2.6.2-r1 (30 Oct 2013)
 



1.1                  net-dialup/minicom/minicom-2.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/minicom/minicom-2.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/minicom/minicom-2.7.ebuild?rev=1.1&content-type=text/plain

Index: minicom-2.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/minicom/minicom-2.7.ebuild,v 1.1 2014/01/01 19:54:42 radhermit Exp $

EAPI=5

inherit eutils toolchain-funcs

STUPID_NUM="3977"

DESCRIPTION="Serial Communication Program"
HOMEPAGE="http://alioth.debian.org/projects/minicom"
SRC_URI="https://alioth.debian.org/frs/download.php/file/${STUPID_NUM}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux"
IUSE="nls"

COMMON_DEPEND="sys-libs/ncurses"
DEPEND="${COMMON_DEPEND}
	nls? ( sys-devel/gettext )"
RDEPEND="${COMMON_DEPEND}
	net-dialup/lrzsz"

DOCS="AUTHORS ChangeLog NEWS README doc/minicom.FAQ"

# Supported languages and translated documentation
# Be sure all languages are prefixed with a single space!
MY_AVAILABLE_LINGUAS=" cs da de es fi fr hu id ja nb pl pt_BR ro ru rw sv vi zh_TW"
IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.3-gentoo-runscript.patch
}

src_configure() {
	econf \
		--sysconfdir="${EPREFIX}"/etc/${PN} \
		$(use_enable nls)
}

src_compile() {
	emake AR="$(tc-getAR)"
}

src_install() {
	default
	insinto /etc/minicom
	doins "${FILESDIR}"/minirc.dfl
}

pkg_preinst() {
	[[ -s ${EROOT}/etc/minicom/minirc.dfl ]] \
		&& rm -f "${ED}"/etc/minicom/minirc.dfl
}