[gentoo-commits] gentoo-x86 commit in sci-visualization/gwyddion: gwyddion-2.30.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    12/11/30 05:51:57

  Modified:             ChangeLog
  Added:                gwyddion-2.30.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.01.21313-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.42                 sci-visualization/gwyddion/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gwyddion/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gwyddion/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gwyddion/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	30 Nov 2012 05:29:17 -0000	1.41
+++ ChangeLog	30 Nov 2012 05:51:57 -0000	1.42
@@ -1,6 +1,11 @@
 # ChangeLog for sci-visualization/gwyddion
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.41 2012/11/30 05:29:17 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.42 2012/11/30 05:51:57 bicatali Exp $
+
+*gwyddion-2.30 (30 Nov 2012)
+
+  30 Nov 2012; Sébastien Fabbro <bicatali@g.o> +gwyddion-2.30.ebuild:
+  Version bump
 
   30 Nov 2012; Sébastien Fabbro <bicatali@g.o> -gwyddion-2.28.ebuild,
   gwyddion-2.29.ebuild:



1.1                  sci-visualization/gwyddion/gwyddion-2.30.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gwyddion/gwyddion-2.30.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gwyddion/gwyddion-2.30.ebuild?rev=1.1&content-type=text/plain

Index: gwyddion-2.30.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/gwyddion-2.30.ebuild,v 1.1 2012/11/30 05:51:57 bicatali Exp $

EAPI=4

PYTHON_DEPEND="python? 2"
AUTOTOOLS_IN_SOURCE_BUILD=1

inherit eutils fdo-mime gnome2-utils python autotools-utils

DESCRIPTION="Framework for Scanning Mode Microscopy data analysis"
HOMEPAGE="http://gwyddion.net/"
SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc fftw gnome kde nls opengl perl python ruby sourceview xml X"

RDEPEND="media-libs/libpng
	x11-libs/cairo
	x11-libs/gtk+:2
	x11-libs/libXmu
	x11-libs/pango
	fftw? ( >=sci-libs/fftw-3 )
	gnome? ( gnome-base/gconf:2 )
	kde? ( >=kde-base/kdelibs-4 )
	opengl? ( virtual/opengl x11-libs/gtkglext )
	perl? ( dev-lang/perl )
	python? ( dev-python/pygtk:2 )
	ruby? ( dev-ruby/narray )
	sourceview? ( x11-libs/gtksourceview:2.0 )
	xml? ( dev-libs/libxml2:2 )"

DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( dev-util/gtk-doc )"

MAKEOPTS+=" V=1"

pkg_setup() {
	use python && python_set_active_version 2
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.25-libpng15.patch
}

src_configure() {
	local myeconfargs=(
		--disable-rpath
		$(use_enable doc gtk-doc)
		$(use_enable nls)
		$(use_enable python pygwy)
		$(use_with perl)
		$(use_with python)
		$(use_with ruby)
		$(use_with fftw fftw3)
		$(use_with opengl gl) \
		$(use_with sourceview gtksourceview)
		$(use_with xml libxml2)
		$(use_with X x)
		$(use_with kde kde4-thumbnailer)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install
	use python && dodoc modules/pygwy/README.pygwy
}

pkg_postinst() {
	use gnome && gnome2_gconf_install
	fdo-mime_desktop_database_update
}

pkg_prerm() {
	use gnome && gnome2_gconf_uninstall
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}