[gentoo-commits] gentoo-x86 commit in sys-cluster/cluster-glue: ChangeLog cluster-glue-1.0.6-r1.ebuild cluster-glue-1.0.6.ebuild

[Kacper Kowalik (xarthisius)]

xarthisius    10/10/06 07:17:12

  Modified:             ChangeLog
  Added:                cluster-glue-1.0.6-r1.ebuild
  Removed:              cluster-glue-1.0.6.ebuild
  Log:
  Don't hardcode uid/gid wrt bug 339857. Thanks to Joe Flasch <jflasch@××.com> for the report. Drop old.
  
  (Portage version: 2.2_rc88/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  sys-cluster/cluster-glue/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	2 Aug 2010 05:46:20 -0000	1.8
+++ ChangeLog	6 Oct 2010 07:17:12 -0000	1.9
@@ -1,6 +1,13 @@
 # ChangeLog for sys-cluster/cluster-glue
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/ChangeLog,v 1.8 2010/08/02 05:46:20 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/ChangeLog,v 1.9 2010/10/06 07:17:12 xarthisius Exp $
+
+*cluster-glue-1.0.6-r1 (06 Oct 2010)
+
+  06 Oct 2010; Kacper Kowalik <xarthisius@g.o>
+  -cluster-glue-1.0.6.ebuild, +cluster-glue-1.0.6-r1.ebuild:
+  Don't hardcode uid/gid wrt bug 339857. Thanks to Joe Flasch
+  <jflasch@××.com> for the report. Drop old.
 
 *cluster-glue-1.0.6 (02 Aug 2010)
 



1.1                  sys-cluster/cluster-glue/cluster-glue-1.0.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: cluster-glue-1.0.6-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.6-r1.ebuild,v 1.1 2010/10/06 07:17:12 xarthisius Exp $

EAPI="2"

MY_P="${P/cluster-}"
inherit autotools multilib eutils base

DESCRIPTION="Library pack for Heartbeat / Pacemaker"
HOMEPAGE="http://www.linux-ha.org/wiki/Cluster_Glue"
SRC_URI="http://hg.linux-ha.org/glue/archive/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
IUSE="doc static-libs"

RDEPEND="app-arch/bzip2
	dev-libs/glib:2
	net-libs/libnet:1.1
	net-misc/curl
	net-misc/iputils
	|| ( net-misc/netkit-telnetd net-misc/telnet-bsd )
	dev-libs/libxml2
	!<sys-cluster/heartbeat-3.0"
DEPEND="${RDEPEND}
	doc? (
		dev-libs/libxslt
		app-text/docbook-xsl-stylesheets
		)"

S="${WORKDIR}/Reusable-Cluster-Components-${MY_P}"

PATCHES=(
	"${FILESDIR}/1.0.5-docs.patch"
	"${FILESDIR}/1.0.5-respect_cflags.patch"
)

pkg_setup() {
	enewgroup haclient
	enewuser  hacluster -1 /dev/null /var/lib/heartbeat haclient
}

src_prepare() {
	base_src_prepare
	eautoreconf
}

src_configure() {
	local myopts

	use doc && myopts=" --enable-doc"
	econf \
		$(use_enable static-libs static) \
		--disable-fatal-warnings \
		--disable-dependency-tracking \
		--docdir=/usr/share/doc/${PF} \
		--enable-libnet \
		--localstatedir=/var \
		--with-ocf-root=/usr/$(get_libdir)/ocf \
		--sysconfdir=/var \
		${myopts} \
		--with-group-id=$(id -g hacluster) \
		--with-ccmuser-id=$(id -u hacluster) \
		--with-daemon-user=hacluster --with-daemon-group=haclient
}

src_install() {
	base_src_install

	dodir /var/lib/heartbeat/cores
	dodir /var/lib/heartbeat/lrm

	keepdir /var/lib/heartbeat/cores
	keepdir /var/lib/heartbeat/lrm

	# init.d file
	cp "${FILESDIR}"/heartbeat-logd.init "${T}/" || die
	sed -i \
		-e "s:%libdir%:$(get_libdir):" \
		"${T}/heartbeat-logd.init" || die
	newinitd "${T}/heartbeat-logd.init" heartbeat-logd || die
	rm "${D}"/etc/init.d/logd
}

pkg_postinst() {
	chown -R hacluster:haclient /var/lib/heartbeat/cores
	chown -R hacluster:haclient /var/lib/heartbeat/lrm
}