[gentoo-commits] repo/gentoo:master commit in: x11-libs/libxcb/

[Matt Turner]

commit:     b5d750a83d3e481c22cee5303647df4d35962f3b
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue May  3 22:24:54 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue May  3 22:31:42 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b5d750a8

x11-libs/libxcb: Version bump to 1.15

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 x11-libs/libxcb/Manifest           |  1 +
 x11-libs/libxcb/libxcb-1.15.ebuild | 54 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)

diff --git a/x11-libs/libxcb/Manifest b/x11-libs/libxcb/Manifest
index 7fce3a4ed083..8ea9468f9062 100644
--- a/x11-libs/libxcb/Manifest
+++ b/x11-libs/libxcb/Manifest
@@ -1 +1,2 @@
 DIST libxcb-1.14.tar.xz 439404 BLAKE2B 63605e02dd32b4d26b3ac6d3b93b7383dbc30701b9a063e8efa5b387215c9325196451f80c7b0b357df1773c6fd1224eea8eeca2a456055a2cdc61082c726111 SHA512 b90a23204b0d2c29d8b115577edb01df0465e02d6a8876550fecd62375d24a5d5f872ddd5946772ddba077cadce75b12c7a6d218469dc30b5b92bc82188e8bc6
+DIST libxcb-1.15.tar.xz 446492 BLAKE2B d50146ee9b822dfd0c24513110e1706cda05ce588f276005167a911d3097275f36be1ce755c42c2b2970e750f10b2b943f3e373b6e55865fba986e29811a3545 SHA512 f6c7d766b7cf9cab6abe948ee424cbae6951dbfe2f76fa58a109cdc05b0f0919dcc4e38176a22ff4b95fc1e38596115317e32ba33b24cae0035a4e30dbcbdad9

diff --git a/x11-libs/libxcb/libxcb-1.15.ebuild b/x11-libs/libxcb/libxcb-1.15.ebuild
new file mode 100644
index 000000000000..f041a8fb59fd
--- /dev/null
+++ b/x11-libs/libxcb/libxcb-1.15.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE=xml
+
+XORG_TARBALL_SUFFIX="xz"
+XORG_MULTILIB=yes
+XORG_DOC=doc
+
+inherit python-any-r1 xorg-3
+
+DESCRIPTION="X C-language Bindings library"
+HOMEPAGE="https://xcb.freedesktop.org/ https://gitlab.freedesktop.org/xorg/lib/libxcb"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc selinux test +xkb"
+RESTRICT="!test? ( test )"
+SLOT="0/1.12"
+
+RDEPEND="
+	>=x11-libs/libXau-1.0.7-r1[${MULTILIB_USEDEP}]
+	>=x11-libs/libXdmcp-1.1.1-r1[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	>=x11-base/xcb-proto-1.15[${MULTILIB_USEDEP}]
+	elibc_Darwin? ( dev-libs/libpthread-stubs )
+	test? ( dev-libs/check[${MULTILIB_USEDEP}] )
+"
+# Note: ${PYTHON_USEDEP} needs to go verbatim
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep '>=x11-base/xcb-proto-1.15[${PYTHON_USEDEP}]')
+	doc? ( app-doc/doxygen[dot] )
+	test? ( dev-libs/libxslt )
+"
+
+python_check_deps() {
+	has_version -b ">=x11-base/xcb-proto-1.15[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	xorg-3_pkg_setup
+}
+
+src_configure() {
+	local XORG_CONFIGURE_OPTIONS=(
+		$(use_enable doc devel-docs)
+		$(use_enable selinux)
+	)
+	xorg-3_src_configure
+}