[gentoo-commits] gentoo-x86 commit in net-dns/bind-tools: ChangeLog bind-tools-9.7.2_p2.ebuild bind-tools-9.4.3_p4.ebuild

[Christian Ruppert (idl0r)]

idl0r       10/10/05 15:47:56

  Modified:             ChangeLog
  Added:                bind-tools-9.7.2_p2.ebuild
  Removed:              bind-tools-9.4.3_p4.ebuild
  Log:
  Version bump to 9.7.2-P2. Remove old 9.4.3-P4.
  
  (Portage version: 2.2_rc88/cvs/Linux x86_64)

Revision  Changes    Path
1.166                net-dns/bind-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/bind-tools/ChangeLog?rev=1.166&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/bind-tools/ChangeLog?rev=1.166&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/bind-tools/ChangeLog?r1=1.165&r2=1.166

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/bind-tools/ChangeLog,v
retrieving revision 1.165
retrieving revision 1.166
diff -u -r1.165 -r1.166
--- ChangeLog	1 Oct 2010 14:11:30 -0000	1.165
+++ ChangeLog	5 Oct 2010 15:47:56 -0000	1.166
@@ -1,6 +1,12 @@
 # ChangeLog for net-dns/bind-tools
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/bind-tools/ChangeLog,v 1.165 2010/10/01 14:11:30 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/bind-tools/ChangeLog,v 1.166 2010/10/05 15:47:56 idl0r Exp $
+
+*bind-tools-9.7.2_p2 (05 Oct 2010)
+
+  05 Oct 2010; Christian Ruppert <idl0r@g.o>
+  -bind-tools-9.4.3_p4.ebuild, +bind-tools-9.7.2_p2.ebuild:
+  Version bump to 9.7.2-P2. Remove old 9.4.3-P4.
 
   01 Oct 2010; Brent Baude <ranger@g.o> bind-tools-9.6.2_p2.ebuild,
   bind-tools-9.7.1.ebuild:



1.1                  net-dns/bind-tools/bind-tools-9.7.2_p2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/bind-tools/bind-tools-9.7.2_p2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/bind-tools/bind-tools-9.7.2_p2.ebuild?rev=1.1&content-type=text/plain

Index: bind-tools-9.7.2_p2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/bind-tools/bind-tools-9.7.2_p2.ebuild,v 1.1 2010/10/05 15:47:56 idl0r Exp $

EAPI="3"

inherit eutils autotools

MY_PN=${PN//-tools}
MY_PV=${PV/_p/-P}
MY_P="${MY_PN}-${MY_PV}"

DESCRIPTION="bind tools: dig, nslookup, host, nsupdate, dnssec-keygen"
HOMEPAGE="http://www.isc.org/software/bind"
SRC_URI="ftp://ftp.isc.org/isc/bind9/${MY_PV}/${MY_P}.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc idn ipv6 ssl urandom xml"

DEPEND="ssl? ( dev-libs/openssl )
	xml? ( dev-libs/libxml2 )
	idn? (
		|| ( sys-libs/glibc dev-libs/libiconv )
		net-dns/idnkit
		)"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# bug 122597
	use idn && {
		cd "${S}"/contrib/idn/idnkit-1.0-src
		epatch "${FILESDIR}"/${PN}-configure.patch
		cd "${S}"
	}

	# bug 231247
	epatch "${FILESDIR}"/${PN}-9.5.0_p1-lwconfig.patch

	eautoreconf
}

src_configure() {
	local myconf=

	has_version sys-libs/glibc || myconf="${myconf} --with-iconv"

	if use urandom; then
		myconf="${myconf} --with-randomdev=/dev/urandom"
	else
		myconf="${myconf} --with-randomdev=/dev/random"
	fi

	econf \
		$(use_enable ipv6) \
		$(use_with idn) \
		$(use_with ssl openssl) \
		$(use_with xml libxml2) \
		${myconf}

	# bug #151839
	echo '#undef SO_BSDCOMPAT' >> config.h
}

src_compile() {
	emake -C lib/ || die "emake lib failed"
	emake -C bin/dig/ || die "emake bin/dig failed"
	emake -C bin/nsupdate/ || die "emake bin/nsupdate failed"
	emake -C bin/dnssec/ || die "emake bin/dnssec failed"
}

src_install() {
	dodoc README CHANGES FAQ || die

	cd "${S}"/bin/dig
	dobin dig host nslookup || die
	doman {dig,host,nslookup}.1 || die

	cd "${S}"/bin/nsupdate
	dobin nsupdate || die
	doman nsupdate.1 || die
	if use doc; then
		dohtml nsupdate.html || die
	fi

	cd "${S}"/bin/dnssec
	dobin dnssec-keygen || die
	doman dnssec-keygen.8 || die

	if use doc; then
		dohtml dnssec-keygen.html || die
	fi
}