[gentoo-commits] repo/gentoo:master commit in: sys-apps/firejail/

[Amadeusz Piotr Żołnowski]

commit:     a4b8ed5f3e50cc472b7edcb824ea9b2b60272358
Author:     Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo <DOT> org>
AuthorDate: Tue Dec  4 22:15:24 2018 +0000
Commit:     Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo <DOT> org>
CommitDate: Tue Dec  4 22:16:13 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a4b8ed5f

sys-apps/firejail: Prepare for xpra removal

Signed-off-by: Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo.org>

 sys-apps/firejail/firejail-0.9.56-r1.ebuild | 47 +++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/sys-apps/firejail/firejail-0.9.56-r1.ebuild b/sys-apps/firejail/firejail-0.9.56-r1.ebuild
new file mode 100644
index 00000000000..6da35dbc147
--- /dev/null
+++ b/sys-apps/firejail/firejail-0.9.56-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils
+
+DESCRIPTION="Security sandbox for any type of processes"
+HOMEPAGE="https://firejail.wordpress.com/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="apparmor +chroot contrib +file-transfer +network
+	+seccomp suid +userns x11"
+
+DEPEND="!sys-apps/firejail-lts
+	apparmor? ( sys-libs/libapparmor )"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PV}-contrib-fix.patch" )
+
+RESTRICT=test
+
+src_prepare() {
+	default
+	find -name Makefile.in -exec sed -i -r \
+			-e '/^\tinstall .*COPYING /d' \
+			-e '/CFLAGS/s: (-O2|-ggdb) : :g' \
+			-e '1iCC=@CC@' {} + || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable apparmor)
+		$(use_enable chroot)
+		$(use_enable contrib contrib-install)
+		$(use_enable file-transfer)
+		$(use_enable network)
+		$(use_enable seccomp)
+		$(use_enable suid)
+		$(use_enable userns)
+		$(use_enable x11)
+	)
+	econf "${myeconfargs[@]}"
+}