[gentoo-commits] gentoo-x86 commit in app-emacs/org-mode: ChangeLog org-mode-7.8.11.ebuild

[Ulrich Mueller (ulm)]

ulm         12/06/05 22:00:37

  Modified:             ChangeLog
  Added:                org-mode-7.8.11.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.144                app-emacs/org-mode/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?rev=1.144&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?rev=1.144&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?r1=1.143&r2=1.144

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v
retrieving revision 1.143
retrieving revision 1.144
diff -u -r1.143 -r1.144
--- ChangeLog	22 Apr 2012 19:51:51 -0000	1.143
+++ ChangeLog	5 Jun 2012 22:00:37 -0000	1.144
@@ -1,6 +1,11 @@
 # ChangeLog for app-emacs/org-mode
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v 1.143 2012/04/22 19:51:51 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v 1.144 2012/06/05 22:00:37 ulm Exp $
+
+*org-mode-7.8.11 (05 Jun 2012)
+
+  05 Jun 2012; Ulrich Müller <ulm@g.o> +org-mode-7.8.11.ebuild:
+  Version bump.
 
 *org-mode-7.8.09 (22 Apr 2012)
 



1.1                  app-emacs/org-mode/org-mode-7.8.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/org-mode-7.8.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/org-mode-7.8.11.ebuild?rev=1.1&content-type=text/plain

Index: org-mode-7.8.11.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/org-mode-7.8.11.ebuild,v 1.1 2012/06/05 22:00:37 ulm Exp $

EAPI=4
NEED_EMACS=22

inherit elisp

DESCRIPTION="An Emacs mode for notes and project planning"
HOMEPAGE="http://www.orgmode.org/"
SRC_URI="http://orgmode.org/org-${PV}.tar.gz"

LICENSE="GPL-3 FDL-1.3 contrib? ( GPL-2 MIT as-is )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-macos"
IUSE="contrib"

S="${WORKDIR}/org-${PV}"
ELISP_PATCHES="${PN}-7.8.03-Makefile.patch"
# Remove autoload file to make sure that it is regenerated with
# the right Emacs version.
ELISP_REMOVE="lisp/org-install.el"
SITEFILE="50${PN}-gentoo-7.8.03.el"

src_compile() {
	emake datadir="${SITEETC}/${PN}"
}

src_install() {
	emake \
		prefix="${ED}/usr" \
		lispdir="${ED}${SITELISP}/${PN}" \
		datadir="${ED}${SITEETC}/${PN}" \
		infodir="${ED}/usr/share/info" \
		install

	cp "${FILESDIR}/${SITEFILE}" "${T}/${SITEFILE}"

	if use contrib; then
		elisp-install ${PN}/contrib contrib/lisp/*org*.el || die
		insinto /usr/share/doc/${PF}/contrib
		doins -r contrib/README contrib/babel contrib/odt contrib/scripts
		find "${ED}/usr/share/doc/${PF}/contrib" -type f -name '.*' \
			-exec rm -f '{}' '+'
		# add the contrib subdirectory to load-path
		sed -ie 's:\(.*@SITELISP@\)\(.*\):&\n\1/contrib\2:' \
			"${T}/${SITEFILE}" || die
	fi

	elisp-site-file-install "${T}/${SITEFILE}" || die
	doinfo doc/org
	dodoc README doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf
}