[gentoo-commits] gentoo-x86 commit in kde-base/plasma-workspace: ChangeLog plasma-workspace-4.11.9.ebuild

[Johannes Huber (johu)]

johu        14/04/29 18:53:04

  Modified:             ChangeLog
  Added:                plasma-workspace-4.11.9.ebuild
  Log:
  Version bump KDE Workspace 4.11.9
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.269                kde-base/plasma-workspace/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.269&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.269&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?r1=1.268&r2=1.269

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v
retrieving revision 1.268
retrieving revision 1.269
diff -u -r1.268 -r1.269
--- ChangeLog	1 Apr 2014 18:24:09 -0000	1.268
+++ ChangeLog	29 Apr 2014 18:53:04 -0000	1.269
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/plasma-workspace
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.268 2014/04/01 18:24:09 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.269 2014/04/29 18:53:04 johu Exp $
+
+*plasma-workspace-4.11.9 (29 Apr 2014)
+
+  29 Apr 2014; Johannes Huber <johu@g.o>
+  +plasma-workspace-4.11.9.ebuild:
+  Version bump KDE Workspace 4.11.9
 
 *plasma-workspace-4.11.8 (01 Apr 2014)
 



1.1                  kde-base/plasma-workspace/plasma-workspace-4.11.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.11.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.11.9.ebuild?rev=1.1&content-type=text/plain

Index: plasma-workspace-4.11.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.11.9.ebuild,v 1.1 2014/04/29 18:53:04 johu Exp $

EAPI=5

DECLARATIVE_REQUIRED="always"
KDE_HANDBOOK="optional"
KMNAME="kde-workspace"
KMMODULE="plasma"
PYTHON_COMPAT=( python2_{6,7} )
OPENGL_REQUIRED="always"
inherit python-single-r1 kde4-meta

DESCRIPTION="Plasma: KDE desktop framework"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug gps json python qalculate semantic-desktop"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

COMMONDEPEND="
	dev-libs/libdbusmenu-qt
	>=dev-qt/qtcore-4.8.4-r3:4
	!kde-misc/ktouchpadenabler
	$(add_kdebase_dep kactivities)
	$(add_kdebase_dep kdelibs 'semantic-desktop?')
	$(add_kdebase_dep kephal)
	$(add_kdebase_dep ksysguard)
	$(add_kdebase_dep libkworkspace)
	$(add_kdebase_dep libplasmaclock 'semantic-desktop?')
	$(add_kdebase_dep libplasmagenericshell)
	$(add_kdebase_dep libtaskmanager)
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXrender
	gps? ( >=sci-geosciences/gpsd-2.37 )
	json? ( dev-libs/qjson )
	python? (
		${PYTHON_DEPS}
		>=dev-python/PyQt4-4.4.0[X,${PYTHON_USEDEP}]
		$(add_kdebase_dep pykde4 "${PYTHON_USEDEP}")
	)
	qalculate? ( sci-libs/libqalculate )
	semantic-desktop? (
		dev-libs/soprano
		$(add_kdebase_dep kdepimlibs)
		$(add_kdebase_dep nepomuk-core)
	)
"
DEPEND="${COMMONDEPEND}
	dev-libs/boost
	x11-proto/compositeproto
	x11-proto/damageproto
	x11-proto/fixesproto
	x11-proto/renderproto
"
RDEPEND="${COMMONDEPEND}
	$(add_kdebase_dep plasma-runtime)
"

KMEXTRA="
	appmenu/
	ktouchpadenabler/
	statusnotifierwatcher/
"
KMEXTRACTONLY="
	kcheckpass/
	krunner/dbus/org.freedesktop.ScreenSaver.xml
	krunner/dbus/org.kde.krunner.App.xml
	ksmserver/org.kde.KSMServerInterface.xml
	ksmserver/screenlocker/
	libs/kephal/
	libs/kworkspace/
	libs/taskmanager/
	libs/plasmagenericshell/
	libs/ksysguard/
	libs/kdm/kgreeterplugin.h
	ksysguard/
"

pkg_setup() {
	if use python ; then
		python-single-r1_pkg_setup
	fi
	kde4-meta_pkg_setup
}

src_unpack() {
	if use handbook; then
		KMEXTRA+=" doc/plasma-desktop"
	fi

	kde4-meta_src_unpack
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_with gps libgps)
		$(cmake-utils_use_with json QJSON)
		$(cmake-utils_use_with python PythonLibrary)
		$(cmake-utils_use_with qalculate)
		$(cmake-utils_use_with semantic-desktop Akonadi)
		$(cmake-utils_use_with semantic-desktop KdepimLibs)
		$(cmake-utils_use_with semantic-desktop NepomukCore)
		$(cmake-utils_use_with semantic-desktop Soprano)
		-DWITH_Xmms=OFF
	)

	kde4-meta_src_configure
}

src_install() {
	kde4-meta_src_install

	if use python; then
		python_optimize "${ED}"
	fi
}