[gentoo-commits] repo/gentoo:master commit in: net-misc/s6-networking/

[Sam James]

commit:     88cff07972f0b4378d56a4a0458988df02713527
Author:     Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Thu Jun 16 11:44:29 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 05:35:15 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=88cff079

net-misc/s6-networking: add 2.5.1.1

Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-misc/s6-networking/Manifest                    |  1 +
 .../s6-networking/s6-networking-2.5.1.1.ebuild     | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/net-misc/s6-networking/Manifest b/net-misc/s6-networking/Manifest
index f3dca2950b68..e9e03e4c193a 100644
--- a/net-misc/s6-networking/Manifest
+++ b/net-misc/s6-networking/Manifest
@@ -1 +1,2 @@
 DIST s6-networking-2.5.1.0.tar.gz 110443 BLAKE2B 489676bcb050d57482b0901742b53ce6cff00e25c1d8effc5c3d96d8e8ad0d32d42a62c15c73155d3b21fcfe6f310fc0f0c020bf945ac1a4b1c7fb9e9785adf4 SHA512 5d64420811d8d8a0034431dccda82b7ddd546f3b7c40ed02e05565c29c3ec14b75477306fea1a1e4aacc898e66e03718d7ac229b85be82d62bfe26c3ffc5fdf8
+DIST s6-networking-2.5.1.1.tar.gz 110431 BLAKE2B 67776a8aa6b02d20ed73c8b8d45e255677c3688973f9ee5f8dcc0de5cfd26146b7ccdc680b22a57e2523d8ab3c08d6e090252e376d09c1edd971a391632d83a0 SHA512 a9c1970cad5b3aeee447cce7c858e8bd88ee378fe456cc68d032f195373dabf658eacf55d9fa39ec635e893116296c1c614b89d97c5045b90dbe745a52e24021

diff --git a/net-misc/s6-networking/s6-networking-2.5.1.1.ebuild b/net-misc/s6-networking/s6-networking-2.5.1.1.ebuild
new file mode 100644
index 000000000000..b5098c86c898
--- /dev/null
+++ b/net-misc/s6-networking/s6-networking-2.5.1.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Suite of small networking utilities for Unix systems"
+HOMEPAGE="https://www.skarnet.org/software/s6-networking/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~x86"
+IUSE="ssl static static-libs"
+
+REQUIRED_USE="static? ( static-libs )
+	ssl? ( !static !static-libs )"
+
+RDEPEND="dev-lang/execline:=[static-libs?]
+	>=dev-libs/skalibs-2.12:=[static-libs?]
+	sys-apps/s6:=[execline,static-libs?]
+	ssl? ( dev-libs/libretls )
+	!static? (
+		net-dns/s6-dns:=
+	)
+"
+DEPEND="${RDEPEND}
+	net-dns/s6-dns[static-libs?]
+"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir=/usr/$(get_libdir)
+		--libdir=/usr/$(get_libdir)/${PN}
+		--with-dynlib=/usr/$(get_libdir)
+		--with-lib=/usr/$(get_libdir)/s6
+		--with-lib=/usr/$(get_libdir)/s6-dns
+		--with-lib=/usr/$(get_libdir)/skalibs
+		--with-sysdeps=/usr/$(get_libdir)/skalibs
+		--enable-shared
+		$(use_enable ssl ssl libtls)
+		$(use_enable static allstatic)
+		$(use_enable static static-libc)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myconf[@]}"
+}