[gentoo-commits] gentoo-x86 commit in net-p2p/transmission: ChangeLog transmission-2.01.ebuild transmission-2.00.ebuild

[Peter Volkov (pva)]

pva         10/06/28 06:59:46

  Modified:             ChangeLog
  Added:                transmission-2.01.ebuild
  Removed:              transmission-2.00.ebuild
  Log:
  Version bump, bug #325841, thank Samuli Suominen for report. Drop not going to be stable.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.120                net-p2p/transmission/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	23 Jun 2010 23:35:36 -0000	1.119
+++ ChangeLog	28 Jun 2010 06:59:46 -0000	1.120
@@ -1,6 +1,13 @@
 # ChangeLog for net-p2p/transmission
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.119 2010/06/23 23:35:36 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.120 2010/06/28 06:59:46 pva Exp $
+
+*transmission-2.01 (28 Jun 2010)
+
+  28 Jun 2010; Peter Volkov <pva@g.o> -transmission-2.00.ebuild,
+  +transmission-2.01.ebuild:
+  Version bump, bug #325841, thank Samuli Suominen for report. Drop not
+  going to be stable.
 
   23 Jun 2010; <chainsaw@g.o> transmission-2.00.ebuild:
   Remanifest because of repackaged distfile. Talked to John Clay on



1.1                  net-p2p/transmission/transmission-2.01.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.01.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.01.ebuild?rev=1.1&content-type=text/plain

Index: transmission-2.01.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-2.01.ebuild,v 1.1 2010/06/28 06:59:46 pva Exp $

EAPI=2
inherit eutils fdo-mime gnome2-utils qt4-r2

DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com/"
SRC_URI="http://download.transmissionbt.com/${PN}/files/${P}.tar.bz2"

LICENSE="MIT GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
IUSE="gnome gtk libnotify sound qt4"

RDEPEND="
	sys-libs/zlib
	>=dev-libs/libevent-1.4.11
	<dev-libs/libevent-2
	>=dev-libs/openssl-0.9.4
	|| ( >=net-misc/curl-7.16.3[ssl]
		>=net-misc/curl-7.16.3[gnutls] )
	gtk? ( >=dev-libs/glib-2.15.5:2
		>=x11-libs/gtk+-2.12:2
		>=dev-libs/dbus-glib-0.70
		gnome? ( >=gnome-base/gconf-2.20.0 )
		libnotify? ( >=x11-libs/libnotify-0.4.3 )
		sound? ( >=media-libs/libcanberra-0.10 ) )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2.2.6b
	sys-devel/gettext
	>=dev-util/intltool-0.40
	dev-util/pkgconfig
	sys-apps/sed"

src_prepare() {
	sed -i -e 's:-ggdb3::g' configure || die
}

src_configure() {
	# cli and daemon doesn't have external deps and are enabled by default
	econf \
		--disable-dependency-tracking \
		$(use_enable gtk) \
		$(use gtk && use_enable libnotify) \
		$(use gtk && use_enable sound libcanberra) \
		$(use gtk && use_enable gnome gconf2)

	use qt4 && cd qt && eqmake4 qtr.pro
}

src_compile() {
	emake || die
	use qt4 && cd qt && { emake || die; }
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS NEWS qt/README.txt
	rm -f "${D}"/usr/share/${PN}/web/LICENSE

	# these are likely outdated for 1.83
	newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon || die
	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon || die

	if use qt4; then
		cd qt
		emake INSTALL_ROOT="${D}/usr" install || die
		make_desktop_entry qtr "Transmission Qt BitTorrent Client" ${PN} \
			"Network;FileTransfer;P2P;Qt"
		use gtk || doicon qt/icons/transmission.png
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}