[gentoo-commits] gentoo-x86 commit in dev-python/pysvn: pysvn-1.6.3-r1.ebuild metadata.xml ChangeLog

[Patrick Lauer (patrick)]

patrick     09/04/01 14:57:02

  Added:                pysvn-1.6.3-r1.ebuild metadata.xml ChangeLog
  Log:
  Initial import, ebuild from sunrise overlay. Thanks to idl0r and all the others who worked on this in the last 2 years.
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-python/pysvn/pysvn-1.6.3-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pysvn/pysvn-1.6.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pysvn/pysvn-1.6.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: pysvn-1.6.3-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pysvn/pysvn-1.6.3-r1.ebuild,v 1.1 2009/04/01 14:57:02 patrick Exp $

inherit eutils python toolchain-funcs

DESCRIPTION="Object-oriented python bindings for subversion"
HOMEPAGE="http://pysvn.tigris.org/"
SRC_URI="http://pysvn.barrys-emacs.org/source_kits/${P}.tar.gz"

LICENSE="Apache-1.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc examples"

DEPEND="dev-util/subversion"
#	>=dev-python/pycxx-5.5.0"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${P}/Source"

src_unpack() {
	python_version

	unpack ${A}

	# skip test test-06 if executed as root otherwise it will fail
	cd "${S/Source/}"
	epatch "${FILESDIR}/skip-root-test.patch"

	cd "${S}"

	# since pysvn-1.6.3: These sources are not compatible with python =< 2.5
	# run the backport command to fix
	if [[ $PYVER_MAJOR -eq 2 ]] && [[ $PYVER_MINOR -lt 6 ]]; then
		einfo "prepare sources for python prior 2.6"
		python setup.py backport || die "backport failed"
	fi

	# needed to generate the Makefile
	python setup.py configure || die "configure failed"

	# we want our CFLAGS as well
	sed -e 's:^\(CCFLAGS=\)\(.*\):\1$(CFLAGS) \2:g' \
		-e 's:^\(CCCFLAGS=\)\(.*\):\1$(CXXFLAGS) \2:g' \
		-e "/^CCC=/s:g++:$(tc-getCXX):" \
		-e "/^CC=/s:gcc:$(tc-getCC):" \
		-i Makefile \
		|| die "sed failed in Makefile"
}

src_test() {
	vecho ">>> Test phase [test]: ${CATEGORY}/${PF}"
	emake test || die "test-pysvn.so failed"
	emake -C ../Tests || die "test failed"
	vecho ">>> Test phase [none]: ${CATEGORY}/${PF}"
}

src_install() {
	local sitedir="$(python_get_sitedir)/${PN}"

	cd pysvn/

	exeinto ${sitedir}
	doexe _pysvn*.so || die "doexe failed"
	insinto ${sitedir}
	doins __init__.py || die "doins failed"

	cd ../

	if use doc; then
		dohtml -r ../Docs/ || die "dohtml failed"
	fi

	if use examples; then
		docinto examples
		dodoc ../Examples/Client/* || die "dodoc examples failed"
	fi
}

pkg_postinst() {
	python_mod_optimize "$(python_get_sitedir)/${PN}"
}

pkg_postrm() {
	python_mod_cleanup "$(python_get_sitedir)/${PN}"
}



1.1                  dev-python/pysvn/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pysvn/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pysvn/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>python</herd>
</pkgmetadata>



1.1                  dev-python/pysvn/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pysvn/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pysvn/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-python/pysvn
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pysvn/ChangeLog,v 1.1 2009/04/01 14:57:02 patrick Exp $

*pysvn-1.6.3-r1 (01 Apr 2009)

  01 Apr 2009; Patrick Lauer <patrick@g.o>
  +files/skip-root-test.patch, +metadata.xml, +pysvn-1.6.3-r1.ebuild:
  Initial import, ebuild from sunrise overlay. Thanks to idl0r and all the
  others who worked on this in the last 2 years.