[gentoo-commits] proj/kde:master commit in: kde-apps/print-manager/

[Andreas Sturmlechner]

commit:     b82100b36ac6c301d0bdff5831753e7ae93859a2
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Nov  2 08:42:07 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Nov  2 08:42:07 2022 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=b82100b3

kde-apps/print-manager: 22.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../print-manager/print-manager-22.08.3.ebuild     | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/kde-apps/print-manager/print-manager-22.08.3.ebuild b/kde-apps/print-manager/print-manager-22.08.3.ebuild
new file mode 100644
index 0000000000..f61901a5d5
--- /dev/null
+++ b/kde-apps/print-manager/print-manager-22.08.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Manage print jobs and printers in Plasma"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+gtk"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	net-print/cups
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	kde-plasma/kde-cli-tools:5
+	gtk? ( app-admin/system-config-printer )
+"
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! use gtk ; then
+		ewarn "By switching off \"gtk\" USE flag, you have chosen to do without"
+		ewarn "an important, though optional, runtime dependency:"
+		ewarn
+		ewarn "app-admin/system-config-printer"
+		ewarn
+		ewarn "${PN} will work nevertheless, but is going to be less comfortable"
+		ewarn "and will show the following error status during runtime:"
+		ewarn
+		ewarn "\"Failed to group devices: 'The name org.fedoraproject.Config.Printing"
+		ewarn "was not provided by any .service files'\""
+	fi
+}