[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-tweak-tool/

[Gilles Dartiguelongue]

commit:     ad537b39569dfc5fe7aaf8c1d27ff5ff942943dd
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 13 16:48:43 2017 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Aug 13 17:02:56 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ad537b39

gnome-extra/gnome-teak-tool: version bump 3.22.0 → 3.24.1

Package-Manager: Portage-2.3.7, Repoman-2.3.3

 gnome-extra/gnome-tweak-tool/Manifest              |  1 +
 .../gnome-tweak-tool-3.24.1.ebuild                 | 70 ++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/gnome-extra/gnome-tweak-tool/Manifest b/gnome-extra/gnome-tweak-tool/Manifest
index 390354f70c1..6c33c61539a 100644
--- a/gnome-extra/gnome-tweak-tool/Manifest
+++ b/gnome-extra/gnome-tweak-tool/Manifest
@@ -1 +1,2 @@
 DIST gnome-tweak-tool-3.22.0.tar.xz 260132 SHA256 3d6ae11e13f6169ee543e573135e1e5697cf92ab8d86570c6f952021ae093abb SHA512 c63c2c61787c78e2e25077cc83b28ae49bffd9e7c39aa78ebd93587ba9640275083f46273cb55986bcc46842449a31f38b77f0e9be69cea551218fd160f6d769 WHIRLPOOL 020c7f87a321558bc9addbd4bced797c458a71834edf6e11d9b40893d03ec9cc57b203d4aba3f3092d549ffcd9b1d96a080ea034ed97752dba8e445cb269e67e
+DIST gnome-tweak-tool-3.24.1.tar.xz 261872 SHA256 19226b374148d660330af9a8341087c2f869bb24355f4dcc87857169eca9f565 SHA512 b76e9a46de07d12b586fb7326fcd51fff1565b831fe8f4d1ab4bbefe36450b5d2cb7c7a168922960894ba57ac9bd412afa61973c034bd1b5f2b45c52eb34adcd WHIRLPOOL 3399af3fefe226c10f51a42e7f3231e2cf7c3b22840694a2671651bcc3ee4366bec3c973be7240020ffe1cdb1b07aae29f1a4b5c9ab4775c53cc505115a92c6d

diff --git a/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.24.1.ebuild b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.24.1.ebuild
new file mode 100644
index 00000000000..eb0b408ac41
--- /dev/null
+++ b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.24.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Tool to customize GNOME 3 options"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/GnomeTweakTool"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	dev-libs/glib:2[dbus]
+	>=dev-python/pygobject-3.10.2:3[${PYTHON_USEDEP}]
+	>=gnome-base/gsettings-desktop-schemas-3.23.3
+"
+# g-s-d, gnome-desktop, gnome-shell etc. needed at runtime for the gsettings schemas
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/gnome-desktop-3.6.0.1:3=[introspection]
+	>=x11-libs/gtk+-3.12:3[introspection]
+
+	net-libs/libsoup:2.4[introspection]
+	x11-libs/libnotify[introspection]
+
+	>=gnome-base/gnome-settings-daemon-3
+	gnome-base/gnome-shell
+	>=gnome-base/nautilus-3
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Add contents of Gentoo's cursor theme directory to cursor theme list
+	eapply "${FILESDIR}/${PN}-3.10.1-gentoo-cursor-themes.patch"
+
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	install_python() {
+		gnome2_src_install
+		python_doscript gnome-tweak-tool || die
+	}
+	python_foreach_impl run_in_build_dir install_python
+}