[gentoo-commits] repo/gentoo:master commit in: media-sound/quodlibet/

[Matthias Maier]

commit:     6b5bc8ecdee473703f2076f2d8c057901f7e0685
Author:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 28 05:23:38 2016 +0000
Commit:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Sun Feb 28 05:25:11 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6b5bc8ec

media-sound/quodlibet: version bump to 3.5.3

Package-Manager: portage-2.2.26

 media-sound/quodlibet/Manifest               |  1 +
 media-sound/quodlibet/quodlibet-3.5.3.ebuild | 70 ++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/media-sound/quodlibet/Manifest b/media-sound/quodlibet/Manifest
index f6e3b39..6be699a 100644
--- a/media-sound/quodlibet/Manifest
+++ b/media-sound/quodlibet/Manifest
@@ -1,2 +1,3 @@
 DIST quodlibet-3.4.1.tar.gz 3318301 SHA256 0500f8f2e052a67e4397b8f7c634f800c9ce37c0456820aedbbef4003354ba78 SHA512 2f77825b696c9bdf411a039c234383ea728af0ca85d103082a17e3e9c8a13d180f06147c82fad1f0bb06c6e37e66ad99e8e5c227a8a32ed23ca981f33344ffc9 WHIRLPOOL 59858b25a13b2ec24ddd332f846713c65d5081843efdae98505879c21c430e56b0792c55790636977c09098a4aaf8250cbc93e7f4f1862dc2bcc55a7ba2f0871
 DIST quodlibet-3.5.1.tar.gz 3421676 SHA256 f168606ce931c30fcd478d354916bb07ae4ca9a61113af9b988e33f73adcb6c6 SHA512 c14447b17d15ad65fc54e4c81b26b190fa4622b1d83b0b7a4c85e42e332585fe067f93a2f0236bab20186072fb2af0a334bb2741660edb282f1e5e7a00a23c9d WHIRLPOOL 733a7bc88797561a27d2757422bb65bb09f366f91824772b54ac99aefa95b8769f1f566772424a8a819fc7e861bead048ab5c2f4ffc4656d46235454739d09b0
+DIST quodlibet-3.5.3.tar.gz 3421980 SHA256 f11f5986c830812278cc10fb5d5beed423212e249f45e7e8ddc6721e726a5ee7 SHA512 ea564360fa960e3130a318fb3925ff70fc46173b4287be67e9bd541855852101083037b9e72730c4064187fdc9e7be92609ff7f6cb865c94d82a86696a9379f4 WHIRLPOOL 179bc20aea94c3e10bb8c776ef17615316fb2a5edc2798b4a1e9eab7c15df77829102003920d1da2d763aaf03fea74eef9ece8c916f0cb47ebf0ca9e631a134e

diff --git a/media-sound/quodlibet/quodlibet-3.5.3.ebuild b/media-sound/quodlibet/quodlibet-3.5.3.ebuild
new file mode 100644
index 0000000..6ba96d3
--- /dev/null
+++ b/media-sound/quodlibet/quodlibet-3.5.3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1 gnome2-utils fdo-mime
+
+DESCRIPTION="audio library tagger, manager, and player for GTK+"
+HOMEPAGE="http://quodlibet.readthedocs.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+dbus gstreamer ipod +udev"
+
+RDEPEND="dev-libs/keybinder:3[introspection]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=media-libs/mutagen-1.22[${PYTHON_USEDEP}]
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0
+		media-plugins/gst-plugins-meta:1.0
+		)
+	!gstreamer? ( media-libs/xine-lib )
+	dbus? (
+		app-misc/media-player-info
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		)
+	ipod? ( media-libs/libgpod[python,${PYTHON_USEDEP}] )
+	udev? ( virtual/udev )
+	!media-plugins/quodlibet-plugins"
+DEPEND="dev-util/intltool"
+REQUIRED_USE="ipod? ( dbus )"
+
+S="${WORKDIR}/${PN}-release-${PV}/${PN}"
+
+src_prepare() {
+	local qlconfig=${PN}/config.py
+
+	if ! use gstreamer; then
+		sed -i -e '/backend/s:gstbe:xinebe:' ${qlconfig} || die
+	fi
+
+	sed -i -e '/gst_pipeline/s:"":"alsasink":' ${qlconfig} || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	dodoc NEWS README
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}