[gentoo-commits] repo/gentoo:master commit in: net-libs/tox/

[Patrice Clement]

commit:     698c70ab0dd8ebceafa05e8ab400967cdb59cba3
Author:     Zetok Zalbavar <zetok <AT> openmailbox <DOT> org>
AuthorDate: Tue Dec 27 07:14:16 2016 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Wed Dec 28 00:07:14 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=698c70ab

net-libs/tox: version bump to 0.1.

Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/3248

Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>

 net-libs/tox/Manifest         |  1 +
 net-libs/tox/tox-0.1.2.ebuild | 77 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index a1cf88a..099f618 100644
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1,2 +1,3 @@
 DIST tox-0.1.1.tar.gz 416532 SHA256 c3a6329731a35c1e9cd8ad204407ddbc408f325056de2b1baa1fc44bc8bfcb37 SHA512 5bdaf047594e943f854fda0f0265167e0dccf05fedfec6b4d9b628b242de23f9dd9b870bbdcca4cb02f9742fa2472e4c7e1047370732cb2ee529467f15e81fc1 WHIRLPOOL 32ee00f6eaf98473ce3de080ba36185da2c225b2037574b55060a12e88876fb1f7df492614fbbb493ba85a44a319f3e0c254c0daec1e8cc18472ba075834039f
+DIST tox-0.1.2.tar.gz 417957 SHA256 605a462f77b497009217b8dbd01108d112e9a8b018473826379f9f4ffa5c0b66 SHA512 39c52dd205205e271b2b15db30a007af89ba9ede00e2717f3ec7431bbfec984984236a493f2a4943cb8deff5d8a4eba1949d9e8332caebadeb352c477b1a5208 WHIRLPOOL 78c72bb16ddc964ce7f69f0721ac864fe64e3c7635614e6ee325af26a8d8ef0142a6cc6f7fd31516ef3f3ce6e2366551a501052809716d72580d39f4e8baaf2a
 DIST tox-0_pre20160904.tar.gz 395495 SHA256 2d4a0d096bdb81b12b10551765fb9f87270e170f10f387f700b3def68cb6c35c SHA512 c0da52ac908141e97e96510a05431cbfb4b9aae81faf4c136c95e21b90a23e3bbe6db88303e48c0f4f3c74ca954229787564b7aa41bfb462afb0d8f8430cdaa1 WHIRLPOOL abd3f61784fac93d983e453515d1e8bc87f7d76651a53ce6f566a277d7ec7c1e03294d95781364ce9ab30f2698c6f5cd552bfa4888f8d5d0d315daf038980c63

diff --git a/net-libs/tox/tox-0.1.2.ebuild b/net-libs/tox/tox-0.1.2.ebuild
new file mode 100644
index 00000000..6e8fafb
--- /dev/null
+++ b/net-libs/tox/tox-0.1.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools systemd user
+
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat"
+SRC_URI="https://github.com/TokTok/c-toxcore/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/0.1"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+av daemon log-debug log-error log-info log-trace log-warn +no-log ntox static-libs test"
+
+REQUIRED_USE="^^ ( no-log log-trace log-debug log-info log-warn log-error )"
+
+RDEPEND="
+	av? ( media-libs/libvpx:=
+		media-libs/opus )
+	daemon? ( dev-libs/libconfig )
+	ntox? ( sys-libs/ncurses:0= )
+	>=dev-libs/libsodium-0.6.1:=[asm,urandom]"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )
+	virtual/pkgconfig"
+
+S=${WORKDIR}/c-toxcore-${PV}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(usex log-trace "--enable-logging --with-log-level=TRACE" "") \
+		$(usex log-debug "--enable-logging --with-log-level=DEBUG" "") \
+		$(usex log-info "--enable-logging --with-log-level=INFO" "") \
+		$(usex log-warn "--enable-logging --with-log-level=WARNING" "") \
+		$(usex log-error "--enable-logging --with-log-level=ERROR" "") \
+		$(use_enable av) \
+		$(use_enable test tests) \
+		$(use_enable ntox) \
+		$(use_enable daemon) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	if use daemon; then
+		newinitd "${FILESDIR}"/initd tox-dht-daemon
+		newconfd "${FILESDIR}"/confd tox-dht-daemon
+		insinto /etc
+		doins "${FILESDIR}"/tox-bootstrapd.conf
+		systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	if use daemon; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 -1 ${PN}
+		if [[ -f ${EROOT%/}/var/lib/tox-dht-bootstrap/key ]]; then
+			ewarn "Backwards compatability with the bootstrap daemon might have been"
+			ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"
+			ewarn "    ${EROOT%/}/var/lib/tox-dht-bootstrap/key"
+			ewarn "    ${EROOT%/}/etc/tox-bootstrapd.conf"
+			ewarn "    ${EROOT%/}/run/tox-dht-bootstrap/tox-dht-bootstrap.pid"
+			ewarn "Then just re-emerge net-libs/tox"
+		fi
+	fi
+}