[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: stunnel-4.27.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     09/04/30 21:45:38

  Modified:             ChangeLog
  Added:                stunnel-4.27.ebuild
  Log:
  Bump to 4.27, fixes #266514.
  (Portage version: 2.2_rc31/cvs/Linux x86_64)

Revision  Changes    Path
1.101                net-misc/stunnel/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.101&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.101&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/ChangeLog?r1=1.100&r2=1.101

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v
retrieving revision 1.100
retrieving revision 1.101
diff -u -r1.100 -r1.101
--- ChangeLog	8 Oct 2008 20:07:51 -0000	1.100
+++ ChangeLog	30 Apr 2009 21:45:38 -0000	1.101
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/stunnel
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.100 2008/10/08 20:07:51 ulm Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.101 2009/04/30 21:45:38 patrick Exp $
+
+*stunnel-4.27 (30 Apr 2009)
+
+  30 Apr 2009; Patrick Lauer <patrick@g.o> +stunnel-4.27.ebuild:
+  Bump to 4.27, fixes #266514.
 
 *stunnel-4.26 (08 Oct 2008)
 



1.1                  net-misc/stunnel/stunnel-4.27.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/stunnel-4.27.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/stunnel-4.27.ebuild?rev=1.1&content-type=text/plain

Index: stunnel-4.27.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/stunnel-4.27.ebuild,v 1.1 2009/04/30 21:45:38 patrick Exp $

inherit autotools ssl-cert eutils

DESCRIPTION="TLS/SSL - Port Wrapper"
HOMEPAGE="http://stunnel.mirt.net/"
SRC_URI="http://www.stunnel.org/download/stunnel/src/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="ipv6 selinux tcpd"

DEPEND="tcpd? ( sys-apps/tcp-wrappers )
	>=dev-libs/openssl-0.9.8k"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-stunnel )"

pkg_setup() {
	enewgroup stunnel
	enewuser stunnel -1 -1 -1 stunnel
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PN}-4.21-libwrap.patch"
	eautoreconf

	# Hack away generation of certificate
	sed -i -e "s/^install-data-local:/do-not-run-this:/" \
		tools/Makefile.in || die "sed failed"
}

src_compile() {
	econf $(use_enable ipv6) \
		$(use_enable tcpd libwrap) || die "econf died"
	emake || die "emake died"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	rm -rf "${D}"/usr/share/doc/${PN}
	rm -f "${D}"/etc/stunnel/stunnel.conf-sample "${D}"/usr/bin/stunnel3 \
		"${D}"/usr/share/man/man8/stunnel.{fr,pl}.8

	# The binary was moved to /usr/bin with 4.21,
	# symlink for backwards compatibility
	dosym ../bin/stunnel /usr/sbin/stunnel

	dodoc AUTHORS BUGS CREDITS PORTS README TODO ChangeLog doc/en/transproxy.txt
	dohtml doc/stunnel.html doc/en/VNC_StunnelHOWTO.html tools/ca.html \
		tools/importCA.html

	insinto /etc/stunnel
	doins "${FILESDIR}"/stunnel.conf
	newinitd "${FILESDIR}"/stunnel.rc6 stunnel

	keepdir /var/run/stunnel
	fowners stunnel:stunnel /var/run/stunnel
}

pkg_postinst() {
	if [ ! -f "${ROOT}"/etc/stunnel/stunnel.key ]; then
		install_cert /etc/stunnel/stunnel
		chown stunnel:stunnel "${ROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
		chmod 0640 "${ROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
	fi

	if [ ! -z "$(grep /etc/stunnel/stunnel.pid \
		"${ROOT}"/etc/stunnel/stunnel.conf )" ] ; then

		ewarn "As of stunnel-4.09, the pid file will be located in /var/run/stunnel."
		ewarn "Please stop stunnel, etc-update, and start stunnel back up to ensure"
		ewarn "the update takes place"
		ewarn
		ewarn "The new location will be /var/run/stunnel/stunnel.pid"
	fi
}