[gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: ChangeLog networkmanager-0.7.1.ebuild networkmanager-0.6.6.ebuild networkmanager-0.6.5_p20070823.ebuild

[Robert Buchholz (rbu)]

rbu         09/04/22 13:30:43

  Modified:             ChangeLog networkmanager-0.6.6.ebuild
  Added:                networkmanager-0.7.1.ebuild
  Removed:              networkmanager-0.6.5_p20070823.ebuild
  Log:
    Version bump by Robert Piasek. Fixes bug 266184.
    Remove 0.6.5 version, remove dependency on gnome/xfce panels as they
    are pulled in via nm-applet anyway (bug 246023).
  (Portage version: 2.1.6.11/cvs/Linux x86_64)

Revision  Changes    Path
1.39                 net-misc/networkmanager/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	21 Apr 2009 15:59:57 -0000	1.38
+++ ChangeLog	22 Apr 2009 13:30:43 -0000	1.39
@@ -1,6 +1,15 @@
 # ChangeLog for net-misc/networkmanager
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.38 2009/04/21 15:59:57 dang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.39 2009/04/22 13:30:43 rbu Exp $
+
+*networkmanager-0.7.1 (22 Apr 2009)
+
+  22 Apr 2009; Robert Buchholz <rbu@g.o>
+  -networkmanager-0.6.5_p20070823.ebuild, networkmanager-0.6.6.ebuild,
+  +networkmanager-0.7.1.ebuild:
+  Version bump by Robert Piasek. Fixes bug 266184.
+  Remove 0.6.5 version, remove dependency on gnome/xfce panels as they
+  are pulled in via nm-applet anyway (bug 246023).
 
   21 Apr 2009; Daniel Gryniewicz <dang@g.o>
   +files/networkmanager-0.7.0-gentoo-dhclient.patch, networkmanager-0.7.0:



1.6                  net-misc/networkmanager/networkmanager-0.6.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.6.6.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.6.6.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.6.6.ebuild?r1=1.5&r2=1.6

Index: networkmanager-0.6.6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.6.6.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- networkmanager-0.6.6.ebuild	22 Jan 2009 16:29:17 -0000	1.5
+++ networkmanager-0.6.6.ebuild	22 Apr 2009 13:30:43 -0000	1.6
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.6.6.ebuild,v 1.5 2009/01/22 16:29:17 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.6.6.ebuild,v 1.6 2009/04/22 13:30:43 rbu Exp $
 
 inherit gnome2 eutils
 
@@ -30,7 +30,6 @@
 	gnome? ( >=x11-libs/gtk+-2.8
 		>=gnome-base/libglade-2
 		>=gnome-base/gnome-keyring-0.4
-		|| ( >=gnome-base/gnome-panel-2 xfce-base/xfce4-panel )
 		>=gnome-base/gconf-2
 		>=gnome-base/libgnomeui-2 )
 	crypt? ( dev-libs/libgcrypt )"



1.1                  net-misc/networkmanager/networkmanager-0.7.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.1.ebuild?rev=1.1&content-type=text/plain

Index: networkmanager-0.7.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.1.ebuild,v 1.1 2009/04/22 13:30:43 rbu Exp $

EAPI="2"
inherit eutils
#autotools

# NetworkManager likes itself with capital letters
MY_PN=${PN/networkmanager/NetworkManager}
MY_P=${MY_PN}-${PV}

DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
SRC_URI="mirror://gnome/sources/NetworkManager/0.7/${MY_P}.tar.bz2"


LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~arm ~amd64 ~ppc ~x86"
IUSE="doc nss gnutls dhclient dhcpcd resolvconf"
# modemmanager"

RDEPEND=">=sys-apps/dbus-1.2
	>=dev-libs/dbus-glib-0.75
	>=sys-apps/hal-0.5.10
	>=net-wireless/wireless-tools-28_pre9
	>=dev-libs/glib-2.16
	>=sys-auth/policykit-0.8
	>=dev-libs/libnl-1.1
	>=net-wireless/wpa_supplicant-0.5.10[dbus]
	|| ( sys-libs/e2fsprogs-libs <sys-fs/e2fsprogs-1.41.0 )

	gnutls? (
		nss? ( >=dev-libs/nss-3.11 )
		!nss? ( dev-libs/libgcrypt
			net-libs/gnutls ) )
	!gnutls? ( >=dev-libs/nss-3.11 )

	dhclient? (
		dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
		!dhcpcd? ( >=net-misc/dhcp-3.0.0 ) )
	!dhclient? ( >=net-misc/dhcpcd-4.0.0_rc3 )

	resolvconf? ( net-dns/openresolv )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/intltool
	net-dialup/ppp
	doc? ( >=dev-util/gtk-doc-1.8 )"

#PDEPEND="modemmanager? ( >=net-misc/modemmanager-0.2 )"

S=${WORKDIR}/${MY_P}

src_prepare() {

	# Fix up the dbus conf file to use plugdev group
	epatch "${FILESDIR}/${PN}-0.7.0-confchanges.patch"

	# bug #266982
	epatch "${FILESDIR}/${PN}-0.7.0-gentoo-dhclient.patch"

#	EPATCH_SOURCE="${WORKDIR}/modem-manager-patchset-0.7.1"
#	EPATCH_SUFFIX="patch"
#	use modemmanager && epatch && autoreconf

}

src_compile() {
	ECONF="--disable-more-warnings \
		--localstatedir=/var \
		--with-distro=gentoo \
		--with-dbus-sys=/etc/dbus-1/system.d
		$(use_enable doc gtk-doc)
		$(use_with doc docs)
		$(use_with resolvconf)"

	# default is dhcpcd (if none or both are specified), ISC dchclient otherwise
	if use dhclient ; then
		if use dhcpcd ; then
			ECONF="${ECONF} --with-dhcp-client=dhcpcd"
		else
			ECONF="${ECONF} --with-dhcp-client=dhclient"
		fi
	else
		ECONF="${ECONF} --with-dhcp-client=dhcpcd"
	fi

	# default is NSS (if none or both are specified), GnuTLS otherwise
	if use gnutls ; then
		if use nss ; then
			ECONF="${ECONF} --with-crypto=nss"
		else
			ECONF="${ECONF} --with-crypto=gnutls"
		fi
	else
		ECONF="${ECONF} --with-crypto=nss"
	fi

	econf ${ECONF}
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# Need to keep the /var/run/NetworkManager directory
	keepdir /var/run/NetworkManager

	# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
	keepdir /etc/NetworkManager/dispatcher.d

	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"

	# Add keyfile plugin support
	keepdir /etc/NetworkManager/system-connections
	insinto /etc/NetworkManager
	newins "${FILESDIR}/nm-system-settings.conf" nm-system-settings.conf \
		|| die "newins failed"
}

pkg_postinst() {
	elog "You need to be in the plugdev group in order to use NetworkManager"
	elog "Problems with your hostname getting changed?"
	elog ""
	elog "Add the following to /etc/dhcp/dhclient.conf"
	elog 'send host-name "YOURHOSTNAME";'
	elog 'supersede host-name "YOURHOSTNAME";'
	elog ""
	elog "If you're using dhcpcd please remove"
	elog "host_name option from /etc/dhcpcd.conf"
	elog ""
	elog "You will need to restart DBUS if this is your first time"
	elog "installing NetworkManager."
	elog ""
	elog "To save system-wide settings as a user, that user needs to have the"
	elog "right policykit privileges. You can add them by running:"
	elog 'polkit-auth --grant org.freedesktop.network-manager-settings.system.modify --user "USERNAME"'
}