[gentoo-commits] repo/gentoo:master commit in: x11-misc/vym/

[Jeroen Roovers]

commit:     06c1474fa8ca9941554f9df65242bc5f1f24d095
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 31 04:26:37 2015 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sat Oct 31 04:27:02 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=06c1474f

x11-misc/vym: Add live ebuild.

Package-Manager: portage-2.2.23

 x11-misc/vym/vym-9999.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/x11-misc/vym/vym-9999.ebuild b/x11-misc/vym/vym-9999.ebuild
new file mode 100644
index 0000000..d12bbab
--- /dev/null
+++ b/x11-misc/vym/vym-9999.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils cmake-utils git-r3
+
+DESCRIPTION="View Your Mind, a mindmap tool"
+HOMEPAGE="http://www.insilmaril.de/vym/"
+EGIT_REPO_URI="git://git.code.sf.net/p/vym/code"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="dbus"
+
+VYM_LINGUAS=( cs_CZ de_DE es fr ia it pt_BR ru sv zh_CN zh_TW )
+IUSE+=" ${VYM_LINGUAS[@]/#/linguas_}"
+
+DEPEND="
+	dev-qt/qtgui:4[qt3support]
+	dev-qt/qtsvg:4
+	dbus? ( dev-qt/qtdbus:4 )
+"
+RDEPEND="
+	${DEPEND}
+	app-arch/zip
+"
+
+DOCS=( README.txt )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.3.22-arrowobj.patch
+
+	sed -i \
+		-e '/lang\/vym_en.ts/d' \
+		CMakeLists.txt || die
+	rm -r lang/vym_en.ts || die
+}
+
+src_configure() {
+	local lingua
+	for lingua in ${VYM_LINGUAS[@]}; do
+		if ! use linguas_${lingua}; then
+			sed -i -e "/lang\/vym_${lingua}.ts/d" CMakeLists.txt || die
+			rm -r lang/vym_${lingua}.ts || die
+		fi
+	done
+
+	local mycmakeargs=(
+		$(cmake-utils_use !dbus NO_DBUS)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	doman doc/vym.1.gz
+	make_desktop_entry vym vym /usr/share/vym/icons/vym.png Education
+}