[gentoo-commits] gentoo-x86 commit in dev-python/blockcanvas: ChangeLog blockcanvas-3.2.1.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    11/01/30 22:31:14

  Modified:             ChangeLog
  Added:                blockcanvas-3.2.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha19_p24/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 dev-python/blockcanvas/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/blockcanvas/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/blockcanvas/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/blockcanvas/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/blockcanvas/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	18 Oct 2010 15:19:01 -0000	1.9
+++ ChangeLog	30 Jan 2011 22:31:14 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/blockcanvas
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/blockcanvas/ChangeLog,v 1.9 2010/10/18 15:19:01 arfrever Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/blockcanvas/ChangeLog,v 1.10 2011/01/30 22:31:14 arfrever Exp $
+
+*blockcanvas-3.2.1 (30 Jan 2011)
+
+  30 Jan 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -blockcanvas-3.2.0.ebuild, +blockcanvas-3.2.1.ebuild:
+  Version bump.
 
 *blockcanvas-3.2.0 (18 Oct 2010)
 



1.1                  dev-python/blockcanvas/blockcanvas-3.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/blockcanvas/blockcanvas-3.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/blockcanvas/blockcanvas-3.2.1.ebuild?rev=1.1&content-type=text/plain

Index: blockcanvas-3.2.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/blockcanvas/blockcanvas-3.2.1.ebuild,v 1.1 2011/01/30 22:31:14 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"
DISTUTILS_SRC_TEST="setup.py"

inherit distutils virtualx

MY_PN="BlockCanvas"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Enthought Tool Suite: Numerical modeling"
HOMEPAGE="http://code.enthought.com/projects/block_canvas/ http://pypi.python.org/pypi/BlockCanvas"
SRC_URI="http://www.enthought.com/repo/ETS/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

RDEPEND=">=dev-python/apptools-3.4.1
	>=dev-python/chaco-3.4.0
	dev-python/configobj
	dev-python/docutils
	>=dev-python/enthoughtbase-3.1.0
	>=dev-python/etsdevtools-3.1.1
	dev-python/greenlet
	dev-python/imaging
	dev-python/numpy
	>=dev-python/scimath-3.0.7
	>=dev-python/traitsgui-3.6.0"
DEPEND="dev-python/setuptools
	doc? ( dev-python/sphinx )
	test? (
		dev-python/nose
		media-fonts/font-cursor-misc
		media-fonts/font-misc-misc
		x11-apps/xhost
	)"

S="${WORKDIR}/${MY_P}"

DOCS="docs/*.txt"
PYTHON_MODNAME="enthought"

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		pushd docs > /dev/null
		emake html || die "Generation of documentation failed"
		popd > /dev/null
	fi
}

src_test() {
	maketype="distutils_src_test" virtualmake
}

src_install() {
	find -name "*LICENSE.txt" -delete
	distutils_src_install

	if use doc; then
		pushd docs/build/html > /dev/null
		insinto /usr/share/doc/${PF}/html
		doins -r [a-z]* _images _static || die "Installation of documentation failed"
		popd > /dev/null
	fi
}