[gentoo-commits] repo/gentoo:master commit in: dev-qt/qtgui/

[Michael Palimaka]

commit:     67afde72d20a053dfc8869302514a959f18dd5f7
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 19 09:21:17 2016 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Fri Feb 19 09:21:55 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67afde72

dev-qt/qtgui: remove old revision

Package-Manager: portage-2.2.27

 dev-qt/qtgui/qtgui-5.5.1.ebuild | 167 ----------------------------------------
 1 file changed, 167 deletions(-)

diff --git a/dev-qt/qtgui/qtgui-5.5.1.ebuild b/dev-qt/qtgui/qtgui-5.5.1.ebuild
deleted file mode 100644
index c406993..0000000
--- a/dev-qt/qtgui/qtgui-5.5.1.ebuild
+++ /dev/null
@@ -1,167 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-QT5_MODULE="qtbase"
-inherit qt5-build
-
-DESCRIPTION="The GUI module and platform plugins for the Qt5 framework"
-
-if [[ ${QT5_BUILD_TYPE} == release ]]; then
-	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~x86"
-fi
-
-# TODO: directfb, linuxfb, kms integration in eglfs
-
-IUSE="accessibility dbus egl eglfs evdev +gif gles2 gtkstyle
-	ibus jpeg libinput +png tslib tuio +udev +xcb"
-REQUIRED_USE="
-	|| ( eglfs xcb )
-	accessibility? ( dbus xcb )
-	eglfs? ( egl )
-	ibus? ( dbus )
-	libinput? ( udev )
-	xcb? ( gles2? ( egl ) )
-"
-
-RDEPEND="
-	dev-libs/glib:2
-	~dev-qt/qtcore-${PV}
-	media-libs/fontconfig
-	>=media-libs/freetype-2.5.5:2
-	>=media-libs/harfbuzz-0.9.40:=
-	>=sys-libs/zlib-1.2.5
-	virtual/opengl
-	dbus? ( ~dev-qt/qtdbus-${PV} )
-	egl? ( media-libs/mesa[egl] )
-	evdev? ( sys-libs/mtdev )
-	gtkstyle? (
-		x11-libs/gtk+:2
-		x11-libs/pango
-		!!x11-libs/cairo[qt4]
-	)
-	gles2? ( media-libs/mesa[gles2] )
-	jpeg? ( virtual/jpeg:0 )
-	libinput? (
-		dev-libs/libinput:=
-		x11-libs/libxkbcommon
-	)
-	png? ( media-libs/libpng:0= )
-	tslib? ( x11-libs/tslib )
-	tuio? ( ~dev-qt/qtnetwork-${PV} )
-	udev? ( virtual/libudev:= )
-	xcb? (
-		x11-libs/libICE
-		x11-libs/libSM
-		x11-libs/libX11
-		>=x11-libs/libXi-1.7.4
-		x11-libs/libXrender
-		>=x11-libs/libxcb-1.10:=[xkb]
-		>=x11-libs/libxkbcommon-0.4.1[X]
-		x11-libs/xcb-util-image
-		x11-libs/xcb-util-keysyms
-		x11-libs/xcb-util-renderutil
-		x11-libs/xcb-util-wm
-	)
-"
-DEPEND="${RDEPEND}
-	evdev? ( sys-kernel/linux-headers )
-	udev? ( sys-kernel/linux-headers )
-"
-PDEPEND="
-	ibus? ( app-i18n/ibus )
-"
-
-QT5_TARGET_SUBDIRS=(
-	src/gui
-	src/openglextensions
-	src/platformheaders
-	src/platformsupport
-	src/plugins/generic
-	src/plugins/imageformats
-	src/plugins/platforms
-	src/plugins/platforminputcontexts
-	src/plugins/platformthemes
-)
-
-QT5_GENTOO_CONFIG=(
-	accessibility:accessibility-atspi-bridge
-	egl
-	eglfs
-	evdev
-	evdev:mtdev:
-	:fontconfig
-	:system-freetype:FREETYPE
-	!:no-freetype:
-	!gif:no-gif:
-	gles2::OPENGL_ES
-	gles2:opengles2:OPENGL_ES_2
-	gtkstyle:gtkstyle:
-	gtkstyle:gtk2:STYLE_GTK
-	!:no-gui:
-	:system-harfbuzz:HARFBUZZ
-	!:no-harfbuzz:
-	jpeg:system-jpeg:IMAGEFORMAT_JPEG
-	!jpeg:no-jpeg:
-	libinput
-	libinput:xkbcommon-evdev:
-	:opengl
-	png:png:
-	png:system-png:IMAGEFORMAT_PNG
-	!png:no-png:
-	tslib
-	udev:libudev:
-	xcb:xcb:
-	xcb:xcb-glx:
-	xcb:xcb-plugin:
-	xcb:xcb-render:
-	xcb:xcb-sm:
-	xcb:xcb-xlib:
-	xcb:xinput2:
-	xcb::XKB
-)
-
-src_prepare() {
-	# egl_x11 is activated when both egl and xcb are enabled
-	use egl && QT5_GENTOO_CONFIG+=(xcb:egl_x11) || QT5_GENTOO_CONFIG+=(egl:egl_x11)
-
-	# avoid automagic dep on qtdbus
-	use dbus || sed -i -e 's/contains(QT_CONFIG, dbus)/false/' \
-		src/platformsupport/platformsupport.pro || die
-
-	qt_use_disable_mod ibus dbus \
-		src/plugins/platforminputcontexts/platforminputcontexts.pro
-
-	# avoid automagic dep on qtnetwork
-	use tuio || sed -i -e '/SUBDIRS += tuiotouch/d' \
-		src/plugins/generic/generic.pro || die
-
-	qt5-build_src_prepare
-}
-
-src_configure() {
-	local myconf=(
-		$(usex dbus -dbus-linked '')
-		$(qt_use egl)
-		$(qt_use eglfs)
-		$(qt_use evdev)
-		$(qt_use evdev mtdev)
-		-fontconfig
-		-system-freetype
-		$(usex gif '' -no-gif)
-		$(qt_use gtkstyle)
-		-system-harfbuzz
-		$(qt_use jpeg libjpeg system)
-		$(qt_use libinput)
-		$(qt_use libinput xkbcommon-evdev)
-		-opengl $(usex gles2 es2 desktop)
-		$(qt_use png libpng system)
-		$(qt_use tslib)
-		$(qt_use udev libudev)
-		$(qt_use xcb xcb system)
-		$(qt_use xcb xkbcommon-x11 system)
-		$(use xcb && echo -xcb-xlib -xinput2 -xkb -xrender)
-	)
-	qt5-build_src_configure
-}