[gentoo-commits] gentoo-x86 commit in dev-games/clanlib: clanlib-2.3.6.ebuild clanlib-2.3.7.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    13/10/28 23:31:47

  Modified:             clanlib-2.3.6.ebuild ChangeLog
  Added:                clanlib-2.3.7.ebuild
  Log:
  version bump and apply upstream patch to stable to fix building with newer mesa (bug #447258)
  
  (Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.5                  dev-games/clanlib/clanlib-2.3.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/clanlib-2.3.6.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/clanlib-2.3.6.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/clanlib-2.3.6.ebuild?r1=1.4&r2=1.5

Index: clanlib-2.3.6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/clanlib/clanlib-2.3.6.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- clanlib-2.3.6.ebuild	4 Dec 2012 11:16:08 -0000	1.4
+++ clanlib-2.3.6.ebuild	28 Oct 2013 23:31:47 -0000	1.5
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/clanlib-2.3.6.ebuild,v 1.4 2012/12/04 11:16:08 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/clanlib-2.3.6.ebuild,v 1.5 2013/10/28 23:31:47 mr_bones_ Exp $
 
 EAPI=4
 inherit flag-o-matic eutils autotools-utils
@@ -44,7 +44,7 @@
 
 S=${WORKDIR}/${MY_P}
 
-PATCHES=( "${FILESDIR}"/${P}-autotools.patch )
+PATCHES=( "${FILESDIR}"/${P}-{autotools,mesa}.patch )
 AUTOTOOLS_AUTORECONF=1
 AUTOTOOLS_IN_SOURCE_BUILD=1
 DOCS=(



1.64                 dev-games/clanlib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/clanlib/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	31 Jan 2013 00:19:04 -0000	1.63
+++ ChangeLog	28 Oct 2013 23:31:47 -0000	1.64
@@ -1,6 +1,14 @@
 # ChangeLog for dev-games/clanlib
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/ChangeLog,v 1.63 2013/01/31 00:19:04 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/ChangeLog,v 1.64 2013/10/28 23:31:47 mr_bones_ Exp $
+
+*clanlib-2.3.7 (28 Oct 2013)
+
+  28 Oct 2013; Michael Sterrett <mr_bones_@g.o> +clanlib-2.3.7.ebuild,
+  +files/clanlib-2.3.6-mesa.patch, +files/clanlib-2.3.7-autotools.patch,
+  clanlib-2.3.6.ebuild:
+  version bump and apply upstream patch to stable to fix building with newer
+  mesa (bug #447258)
 
   31 Jan 2013; Michael Sterrett <mr_bones_@g.o> -clanlib-2.3.4.ebuild,
   -files/clanlib-2.3.4-autotools.patch:



1.1                  dev-games/clanlib/clanlib-2.3.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/clanlib-2.3.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/clanlib-2.3.7.ebuild?rev=1.1&content-type=text/plain

Index: clanlib-2.3.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/clanlib-2.3.7.ebuild,v 1.1 2013/10/28 23:31:47 mr_bones_ Exp $

EAPI=4
inherit flag-o-matic eutils autotools-utils

MY_P=ClanLib-${PV}

DESCRIPTION="multi-platform game development library"
HOMEPAGE="http://www.clanlib.org/"
SRC_URI="http://clanlib.org/download/releases-2.0/${MY_P}.tgz"

LICENSE="ZLIB"
SLOT="2.3"
KEYWORDS="~amd64 ~x86" #not big endian safe #82779
IUSE="doc ipv6 mikmod opengl sound sqlite sse2 static-libs vorbis X"
REQUIRED_USE="opengl? ( X )"

RDEPEND="sys-libs/zlib
	X? (
		media-libs/libpng
		virtual/jpeg
		media-libs/freetype
		media-libs/fontconfig
		opengl? ( virtual/opengl )
		app-arch/bzip2
		x11-libs/libX11
	)
	sqlite? ( dev-db/sqlite )
	sound? ( media-libs/alsa-lib )
	mikmod? (
		media-libs/libmikmod
		media-libs/alsa-lib
	)
	vorbis? (
		media-libs/libogg
		media-libs/libvorbis
		media-libs/alsa-lib
	)"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen dev-lang/perl )"

S=${WORKDIR}/${MY_P}

PATCHES=( "${FILESDIR}"/${P}-autotools.patch )
AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_IN_SOURCE_BUILD=1
DOCS=(
	CODING_STYLE
	CREDITS
	PATCHES
	README
)

src_configure() {
	myeconfargs=(
		$(use_enable doc docs)
		$(use_enable sse2)
		$(use_enable opengl clanGL)
		$(use_enable opengl clanGL1)
		$(use_enable opengl clanGUI)
		$(use_enable X clanDisplay)
		$(use_enable vorbis clanVorbis)
		$(use_enable mikmod clanMikMod)
		$(use_enable sqlite clanSqlite)
		$(use_enable ipv6 getaddr)
	)
	use sound \
		|| use vorbis \
		|| use mikmod \
		|| myeconfargs+=( --disable-clanSound )
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	use doc && autotools-utils_src_compile html
}

# html files are keeped in a directory that is dependent on the SLOT
# so to keep eventual bookmarks to the doc from version to version
src_install() {
	autotools-utils_src_install
	if use doc ; then
		emake DESTDIR="${D}" install-html
		dodoc -r Examples Resources
	fi
}