[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: ChangeLog alsa-utils-1.0.20-r4.ebuild alsa-utils-1.0.20-r2.ebuild alsa-utils-1.0.20-r3.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    09/08/04 09:40:23

  Modified:             ChangeLog
  Added:                alsa-utils-1.0.20-r4.ebuild
  Removed:              alsa-utils-1.0.20-r2.ebuild
                        alsa-utils-1.0.20-r3.ebuild
  Log:
  Fix alsaconf to write /etc/modprobe.d/alsa.conf instead of /etc/modules.d/alsa wrt #251081.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.272                media-sound/alsa-utils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.272&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.272&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?r1=1.271&r2=1.272

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v
retrieving revision 1.271
retrieving revision 1.272
diff -u -r1.271 -r1.272
--- ChangeLog	2 Aug 2009 11:27:28 -0000	1.271
+++ ChangeLog	4 Aug 2009 09:40:23 -0000	1.272
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/alsa-utils
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.271 2009/08/02 11:27:28 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.272 2009/08/04 09:40:23 ssuominen Exp $
+
+*alsa-utils-1.0.20-r4 (04 Aug 2009)
+
+  04 Aug 2009; Samuli Suominen <ssuominen@g.o>
+  +alsa-utils-1.0.20-r4.ebuild, +files/alsa-utils-1.0.20-modprobe.d.patch:
+  Fix alsaconf to write /etc/modprobe.d/alsa.conf instead of
+  /etc/modules.d/alsa wrt #251081.
 
 *alsa-utils-1.0.20-r3 (02 Aug 2009)
 



1.1                  media-sound/alsa-utils/alsa-utils-1.0.20-r4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.20-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.20-r4.ebuild?rev=1.1&content-type=text/plain

Index: alsa-utils-1.0.20-r4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.20-r4.ebuild,v 1.1 2009/08/04 09:40:23 ssuominen Exp $

EAPI=2
inherit eutils

MY_P=${P/_rc/rc}

DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/utils/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="doc nls minimal"

DEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-${PV}
	doc? ( app-text/xmlto )"
RDEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-${PV}
	virtual/modutils
	!minimal? ( sys-apps/pciutils )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	if [[ -e "${ROOT}etc/modules.d/alsa" ]]; then
		eerror "Obsolete config /etc/modules.d/alsa found."
		die "Move /etc/modules.d/alsa to /etc/modprobe.d/alsa.conf."
	fi

	if [[ -e "${ROOT}etc/modprobe.d/alsa" ]]; then
		eerror "Obsolete config /etc/modprobe.d/alsa found."
		die "Move /etc/modprobe.d/alsa to /etc/modprobe.d/alsa.conf."
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-modprobe.d.patch
}

src_configure() {
	local myconf=""
	use doc || myconf="--disable-xmlto"

	econf ${myconf} \
		$(use_enable nls)
}

src_install() {
	local ALSA_UTILS_DOCS="ChangeLog README TODO
		seq/aconnect/README.aconnect
		seq/aseqnet/README.aseqnet"

	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc ${ALSA_UTILS_DOCS} || die
	newdoc alsamixer/README README.alsamixer || die

	newinitd "${FILESDIR}/alsasound.initd-r4" alsasound
	newconfd "${FILESDIR}/alsasound.confd-r3" alsasound
	insinto /etc/modprobe.d
	newins "${FILESDIR}/alsa-modules.conf-rc" alsa.conf

	keepdir /var/lib/alsa
}

pkg_postinst() {
	echo
	elog "To take advantage of the init script, and automate the process of"
	elog "saving and restoring sound-card mixer levels you should"
	elog "add alsasound to the boot runlevel. You can do this as"
	elog "root like so:"
	elog "	# rc-update add alsasound boot"
	echo
	elog "The script will load ALSA modules, if you choose to use a modular"
	elog "configuration. The Gentoo ALSA developers recommend you to build"
	elog "your audio drivers into the kernel unless the device is hotpluggable"
	elog "or you need to supply specific options (such as model= to HD Audio)."
	echo
	ewarn "Automated unloading of ALSA modules is deprecated and unsupported."
	ewarn "Should you choose to use it, bug reports will not be accepted."
	echo
	if use minimal; then
		ewarn "The minimal use flag disables the dependency on pciutils that"
		ewarn "is needed by alsaconf at runtime."
	fi
}