[gentoo-commits] gentoo-x86 commit in net-im/qtwitter: ChangeLog qtwitter-0.10.0.ebuild

[Dominik Kapusta (ayoy)]

ayoy        09/11/01 18:59:46

  Modified:             ChangeLog
  Added:                qtwitter-0.10.0.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc48/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 net-im/qtwitter/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/qtwitter/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/qtwitter/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/qtwitter/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/qtwitter/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	1 Oct 2009 17:08:15 -0000	1.17
+++ ChangeLog	1 Nov 2009 18:59:45 -0000	1.18
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/qtwitter
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/qtwitter/ChangeLog,v 1.17 2009/10/01 17:08:15 ayoy Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/qtwitter/ChangeLog,v 1.18 2009/11/01 18:59:45 ayoy Exp $
+
+*qtwitter-0.10.0 (01 Nov 2009)
+
+  01 Nov 2009; Dominik Kapusta <ayoy@g.o> +qtwitter-0.10.0.ebuild:
+  Version bump
 
 *qtwitter-0.9.2 (01 Oct 2009)
 



1.1                  net-im/qtwitter/qtwitter-0.10.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/qtwitter/qtwitter-0.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/qtwitter/qtwitter-0.10.0.ebuild?rev=1.1&content-type=text/plain

Index: qtwitter-0.10.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/qtwitter/qtwitter-0.10.0.ebuild,v 1.1 2009/11/01 18:59:45 ayoy Exp $

EAPI="2"

inherit qt4

DESCRIPTION="A Qt-based microblogging client"
HOMEPAGE="http://www.qt-apps.org/content/show.php/qTwitter?content=99087"
SRC_URI="http://files.ayoy.net/qtwitter/release/${PV}/src/${P}-src.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

DEPEND=">=x11-libs/qt-gui-4.5:4
	>=x11-libs/qt-dbus-4.5:4
	>=dev-libs/qoauth-1.0"
RDEPEND="${DEPEND}"

QTWITTER_LANGS="nb_NO pt_BR"
QTWITTER_NOLONGLANGS="ca_ES cs_CZ de_DE es_ES fr_FR it_IT ja_JP pl_PL"

for L in $QTWITTER_LANGS; do
	IUSE="$IUSE linguas_$L"
done
for L in $QTWITTER_NOLONGLANGS; do
	IUSE="$IUSE linguas_${L%_*}"
done

src_prepare() {
	qt4_src_prepare
	echo "CONFIG += nostrip" >> "${S}"/${PN}.pro

	local langs=
	for lingua in $LINGUAS; do
		if has $lingua $QTWITTER_LANGS; then
			langs="$langs ${lingua}"
		else
			for a in $QTWITTER_NOLONGLANGS; do
				if [[ $lingua == ${a%_*} ]]; then
					langs="$langs ${a}"
				fi
			done
		fi
	done

	# remove translations and add only the selected ones
	sed -e '/^ *LANGS/,/^$/s/^/#/' \
		-e "/LANGS =/s/.*/LANGS = ${langs}/" \
		-i translations/translations.pri || die "sed translations failed"
	# fix insecure runpaths
	sed -e '/-Wl,-rpath,\$\${DESTDIR}/d' \
		-i qtwitter-app/qtwitter-app.pro || die "sed rpath failed"
}

src_configure() {
	eqmake4 ${PN}.pro PREFIX="/usr"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
	dodoc README CHANGELOG || die "dodoc failed"
}