[gentoo-commits] gentoo-x86 commit in dev-games/clanlib: ChangeLog clanlib-2.3.4.ebuild

[Alfredo Tupone (tupone)]

tupone      12/02/06 13:56:37

  Modified:             ChangeLog
  Added:                clanlib-2.3.4.ebuild
  Log:
  Version bump to 2.4.3 Bug #288218
  
  (Portage version: 2.1.10.44/cvs/Linux i686)

Revision  Changes    Path
1.50                 dev-games/clanlib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/clanlib/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	15 Sep 2011 02:31:01 -0000	1.49
+++ ChangeLog	6 Feb 2012 13:56:37 -0000	1.50
@@ -1,6 +1,12 @@
 # ChangeLog for dev-games/clanlib
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/ChangeLog,v 1.49 2011/09/15 02:31:01 ssuominen Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/ChangeLog,v 1.50 2012/02/06 13:56:37 tupone Exp $
+
+*clanlib-2.3.4 (06 Feb 2012)
+
+  06 Feb 2012; Tupone Alfredo <tupone@g.o> +clanlib-2.3.4.ebuild,
+  +files/clanlib-2.3.4-autotools.patch:
+  Version bump to 2.4.3 Bug #288218 by proDOOMman
 
   15 Sep 2011; Samuli Suominen <ssuominen@g.o> clanlib-0.8.1.ebuild,
   +files/clanlib-0.8.1-libpng15.patch:



1.1                  dev-games/clanlib/clanlib-2.3.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/clanlib-2.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/clanlib/clanlib-2.3.4.ebuild?rev=1.1&content-type=text/plain

Index: clanlib-2.3.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/clanlib/clanlib-2.3.4.ebuild,v 1.1 2012/02/06 13:56:37 tupone Exp $

EAPI=2
inherit flag-o-matic eutils autotools-utils

MY_P=ClanLib-${PV}

DESCRIPTION="multi-platform game development library"
HOMEPAGE="http://www.clanlib.org/"
SRC_URI="http://clanlib.org/download/releases-2.0/${MY_P}.tgz"

LICENSE="ZLIB"
SLOT="2.3"
KEYWORDS="~amd64 ~x86" #not big endian safe #82779
IUSE="doc ipv6 mikmod opengl sound sqlite sse2 static-libs vorbis X"

RDEPEND="sys-libs/zlib
	X? (
		media-libs/libpng
		virtual/jpeg
		media-libs/freetype
		media-libs/fontconfig
		opengl? ( virtual/opengl )
		app-arch/bzip2
		x11-libs/libX11
	)
	sqlite? ( dev-db/sqlite )
	sound? (
		media-libs/alsa-lib
		mikmod? ( media-libs/libmikmod )
		vorbis? (
			media-libs/libogg
			media-libs/libvorbis
		)
	)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen dev-lang/perl )"

S="${WORKDIR}"/${MY_P}

PATCHES=( "${FILESDIR}"/${P}-autotools.patch )
AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_IN_SOURCE_BUILD=1
DOCS=(
	CODING_STYLE
	CREDITS
	PATCHES
	README
)

src_configure() {
	myeconfargs=(
		--disable-dependency-tracking
		$(use_enable doc docs)
		$(use_enable sse2)
		$(use_enable opengl clanGL)
		$(use_enable opengl clanGL1)
		$(use_enable opengl clanGUI)
		$(use_enable X clanDisplay)
		$(use_enable sound clanSound)
		$(use_enable vorbis clanVorbis)
		$(use_enable mikmod clanMikMod)
		$(use_enable sqlite clanSqlite)
		$(use_enable ipv6 getaddr)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	use doc && autotools-utils_src_compile html
}

# html files are keeped in a directory that is dependent on the SLOT
# so to keep eventual bookmarks to the doc from version to version
src_install() {
	autotools-utils_src_install
	if use doc ; then
		emake DESTDIR="${D}" install-html || die "emake html-install failed"
		cp -r Examples Resources "${D}"/usr/share/doc/${PF}/ \
			|| die "Copying failed"
	fi
}