[gentoo-commits] gentoo-x86 commit in net-irc/weechat: weechat-0.4.2.ebuild ChangeLog

[Tomas Chvatal (scarabeus)]

scarabeus    13/10/29 17:12:48

  Modified:             ChangeLog
  Added:                weechat-0.4.2.ebuild
  Log:
  Version bump to 0.4.2 wrt bug#489744.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 8EEE3BE8)

Revision  Changes    Path
1.135                net-irc/weechat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/ChangeLog?rev=1.135&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/ChangeLog?rev=1.135&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/ChangeLog?r1=1.134&r2=1.135

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/weechat/ChangeLog,v
retrieving revision 1.134
retrieving revision 1.135
diff -u -r1.134 -r1.135
--- ChangeLog	27 Jul 2013 20:11:11 -0000	1.134
+++ ChangeLog	29 Oct 2013 17:12:48 -0000	1.135
@@ -1,6 +1,11 @@
 # ChangeLog for net-irc/weechat
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/weechat/ChangeLog,v 1.134 2013/07/27 20:11:11 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/weechat/ChangeLog,v 1.135 2013/10/29 17:12:48 scarabeus Exp $
+
+*weechat-0.4.2 (29 Oct 2013)
+
+  29 Oct 2013; Tomáš Chvátal <scarabeus@g.o> +weechat-0.4.2.ebuild:
+  Version bump to 0.4.2 wrt bug#489744.
 
   27 Jul 2013; Alexis Ballier <aballier@g.o> weechat-0.4.1.ebuild,
   weechat-9999.ebuild:



1.1                  net-irc/weechat/weechat-0.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/weechat-0.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/weechat-0.4.2.ebuild?rev=1.1&content-type=text/plain

Index: weechat-0.4.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/weechat/weechat-0.4.2.ebuild,v 1.1 2013/10/29 17:12:48 scarabeus Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 python3_2 python3_3 )

EGIT_REPO_URI="git://git.sv.gnu.org/weechat.git"
[[ ${PV} == "9999" ]] && GIT_ECLASS="git-2"
inherit eutils python-single-r1 multilib cmake-utils ${GIT_ECLASS}

DESCRIPTION="Portable and multi-interface IRC client."
HOMEPAGE="http://weechat.org/"
[[ ${PV} == "9999" ]] || SRC_URI="http://${PN}.org/files/src/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
if [[ ${PV} == "9999" ]]; then
	KEYWORDS=""
else
	KEYWORDS="~amd64 ~ppc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
fi

NETWORKS="+irc"
PLUGINS="+alias +charset +fifo +logger +relay +rmodifier +scripts +spell +xfer"
#INTERFACES="+ncurses gtk"
SCRIPT_LANGS="guile lua +perl +python ruby tcl"
IUSE="${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS} doc nls +ssl"

RDEPEND="
	dev-libs/libgcrypt
	net-misc/curl[ssl]
	sys-libs/ncurses
	sys-libs/zlib
	charset? ( virtual/libiconv )
	guile? ( dev-scheme/guile )
	lua? ( dev-lang/lua[deprecated] )
	nls? ( virtual/libintl )
	perl? ( dev-lang/perl )
	python? ( ${PYTHON_DEPS} )
	ruby? ( >=dev-lang/ruby-1.9 )
	ssl? ( net-libs/gnutls )
	spell? ( app-text/aspell )
	tcl? ( >=dev-lang/tcl-8.4.15 )
"
#	ncurses? ( sys-libs/ncurses )
#	gtk? ( x11-libs/gtk+:2 )
DEPEND="${RDEPEND}
	doc? (
		app-text/asciidoc
		dev-util/source-highlight
	)
	nls? ( >=sys-devel/gettext-0.15 )
"

DOCS="AUTHORS ChangeLog NEWS README"

#REQUIRED_USE=" || ( ncurses gtk )"

LANGS=( cs de es fr hu it ja pl pt_BR ru )
for X in "${LANGS[@]}" ; do
	IUSE="${IUSE} linguas_${X}"
done

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_prepare() {
	local i

	# fix libdir placement
	sed -i \
		-e "s:lib/:$(get_libdir)/:g" \
		-e "s:lib\":$(get_libdir)\":g" \
		CMakeLists.txt || die "sed failed"

	# install only required translations
	for i in "${LANGS[@]}" ; do
		if ! use linguas_${i} ; then
			sed -i \
				-e "/${i}.po/d" \
				po/CMakeLists.txt || die
		fi
	done

	# install only required documentation ; en always
	for i in `grep ADD_SUBDIRECTORY doc/CMakeLists.txt \
			| sed -e 's/.*ADD_SUBDIRECTORY( \(..\) ).*/\1/' -e '/en/d'`; do
		if ! use linguas_${i} ; then
			sed -i \
				-e '/ADD_SUBDIRECTORY( '${i}' )/d' \
				doc/CMakeLists.txt || die
		fi
	done
}

src_configure() {
	# $(cmake-utils_use_enable gtk)
	# $(cmake-utils_use_enable ncurses)
	local mycmakeargs=(
		"-DENABLE_NCURSES=ON"
		"-DENABLE_LARGEFILE=ON"
		"-DENABLE_DEMO=OFF"
		"-DENABLE_GTK=OFF"
		"-DPYTHON_EXECUTABLE=${PYTHON}"
		$(cmake-utils_use_enable alias)
		$(cmake-utils_use_enable doc)
		$(cmake-utils_use_enable charset)
		$(cmake-utils_use_enable fifo)
		$(cmake-utils_use_enable guile)
		$(cmake-utils_use_enable irc)
		$(cmake-utils_use_enable logger)
		$(cmake-utils_use_enable lua)
		$(cmake-utils_use_enable nls)
		$(cmake-utils_use_enable perl)
		$(cmake-utils_use_enable python)
		$(cmake-utils_use_enable relay)
		$(cmake-utils_use_enable rmodifier)
		$(cmake-utils_use_enable ruby)
		$(cmake-utils_use_enable scripts)
		$(cmake-utils_use_enable scripts script)
		$(cmake-utils_use_enable spell ASPELL)
		$(cmake-utils_use_enable ssl GNUTLS)
		$(cmake-utils_use_enable tcl)
		$(cmake-utils_use_enable xfer)
	)

	cmake-utils_src_configure
}