[gentoo-commits] gentoo-x86 commit in app-arch/tar: ChangeLog tar-1.21-r1.ebuild

[Mike Frysinger (vapier)]

vapier      08/12/29 10:03:44

  Modified:             ChangeLog
  Added:                tar-1.21-r1.ebuild
  Log:
  Revert an upstream change that breaks when piping data into tar as pointed out by Zac Medico #252680 by Etienne Hilson.
  (Portage version: 2.2_rc18/cvs/Linux 2.6.28 x86_64)

Revision  Changes    Path
1.138                app-arch/tar/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/tar/ChangeLog?rev=1.138&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/tar/ChangeLog?rev=1.138&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/tar/ChangeLog?r1=1.137&r2=1.138

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v
retrieving revision 1.137
retrieving revision 1.138
diff -u -r1.137 -r1.138
--- ChangeLog	27 Dec 2008 03:24:11 -0000	1.137
+++ ChangeLog	29 Dec 2008 10:03:44 -0000	1.138
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/tar
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v 1.137 2008/12/27 03:24:11 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v 1.138 2008/12/29 10:03:44 vapier Exp $
+
+*tar-1.21-r1 (29 Dec 2008)
+
+  29 Dec 2008; Mike Frysinger <vapier@g.o>
+  +files/tar-1.21-revert-pipe.patch, +tar-1.21-r1.ebuild:
+  Revert an upstream change that breaks when piping data into tar as pointed
+  out by Zac Medico #252680 by Etienne Hilson.
 
 *tar-1.21 (27 Dec 2008)
 



1.1                  app-arch/tar/tar-1.21-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/tar/tar-1.21-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/tar/tar-1.21-r1.ebuild?rev=1.1&content-type=text/plain

Index: tar-1.21-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/tar-1.21-r1.ebuild,v 1.1 2008/12/29 10:03:44 vapier Exp $

inherit flag-o-matic eutils

DESCRIPTION="Use this to make tarballs :)"
HOMEPAGE="http://www.gnu.org/software/tar/"
SRC_URI="http://ftp.gnu.org/gnu/tar/${P}.tar.bz2
	ftp://alpha.gnu.org/gnu/tar/${P}.tar.bz2
	mirror://gnu/tar/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls static userland_GNU"

RDEPEND=""
DEPEND="${RDEPEND}
	nls? ( >=sys-devel/gettext-0.10.35 )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${P}-revert-pipe.patch #252680

	if ! use userland_GNU ; then
		sed -i \
			-e 's:/backup\.sh:/gbackup.sh:' \
			scripts/{backup,dump-remind,restore}.in \
			|| die "sed non-GNU"
	fi
}

src_compile() {
	local myconf
	use static && append-ldflags -static
	use userland_GNU || myconf="--program-prefix=g"
	# Work around bug in sandbox #67051
	gl_cv_func_chown_follows_symlink=yes \
	econf \
		--enable-backup-scripts \
		--bindir=/bin \
		--libexecdir=/usr/sbin \
		$(use_enable nls) \
		${myconf} || die
	emake || die "emake failed"
}

src_install() {
	local p=""
	use userland_GNU || p=g

	emake DESTDIR="${D}" install || die "make install failed"

	if [[ -z ${p} ]] ; then
		# a nasty yet required piece of baggage
		exeinto /etc
		doexe "${FILESDIR}"/rmt || die
	fi

	dodoc AUTHORS ChangeLog* NEWS README* PORTS THANKS
	newman "${FILESDIR}"/tar.1 ${p}tar.1
	mv "${D}"/usr/sbin/${p}backup{,-tar}
	mv "${D}"/usr/sbin/${p}restore{,-tar}

	rm -f "${D}"/usr/$(get_libdir)/charset.alias
}