[gentoo-commits] repo/gentoo:master commit in: net-wireless/gr-osmosdr/

[Rick Farina]

commit:     c03162206d4ccbb38555b8b932f7c517d51087bf
Author:     Rick Farina <zerochaos <AT> gentoo <DOT> org>
AuthorDate: Fri Sep  4 16:11:38 2020 +0000
Commit:     Rick Farina <zerochaos <AT> gentoo <DOT> org>
CommitDate: Fri Sep  4 16:22:24 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c0316220

net-wireless/gr-osmosdr: bump

Package-Manager: Portage-3.0.5, Repoman-3.0.1
Signed-off-by: Rick Farina <zerochaos <AT> gentoo.org>

 net-wireless/gr-osmosdr/Manifest                |  1 +
 net-wireless/gr-osmosdr/gr-osmosdr-0.2.2.ebuild | 70 +++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/net-wireless/gr-osmosdr/Manifest b/net-wireless/gr-osmosdr/Manifest
index 5a85526c102..0c5c758fe23 100644
--- a/net-wireless/gr-osmosdr/Manifest
+++ b/net-wireless/gr-osmosdr/Manifest
@@ -1,2 +1,3 @@
 DIST gr-osmosdr-0.1.5.tar.gz 278257 BLAKE2B f63704bd8d7e1fc86cfab256e8813716ac56a4b962f37d9e027df6234ee8e6d78a9d8459408d31ace4a3d6f46edfca0cc1eb9c1004b7052332ead1528cc5ec4b SHA512 5c028dcacf3cb94696eecdd31f4f09b31158c8ce12646d577535ba20942103899e5e21f001f2dd7d0a56eb58f17c2aa849139b495c61e21b60dd6678444b0983
 DIST gr-osmosdr-0.2.0.tar.gz 251163 BLAKE2B 036a4439c5c27ae3143ef3be6e76f94bf3e0524509ffc58ad19379fa0adc9477bd704b7e88fffd46ed9e5528ae539d875b4e496a77ea392e8eef117fc57a3af1 SHA512 96eb8ff0a05cf0d5b49384cdc80e0a3d924ba452485acbe852266fd73a5335668b40454421d9f5a52ea610f7100557e51d6a5d9cf6931fe68e8757eb5f02d126
+DIST gr-osmosdr-0.2.2.tar.gz 251425 BLAKE2B e1e29280b84139bf4b1b25ee35553f48abe7f26f9f240852c25f883ec6df406157d9b734035fd6df87e50b6d6f8ddab679ea91430558716acba05a9a64844c3d SHA512 42aef6efd35fd9184a371202398455de7cac3a88374e761359ab837a329495b653a95f5641f0a9533daeaa08c0d7fd5649b1b33359009dd4e8a3b9b24aedd2af

diff --git a/net-wireless/gr-osmosdr/gr-osmosdr-0.2.2.ebuild b/net-wireless/gr-osmosdr/gr-osmosdr-0.2.2.ebuild
new file mode 100644
index 00000000000..f77ffadc343
--- /dev/null
+++ b/net-wireless/gr-osmosdr/gr-osmosdr-0.2.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit cmake-utils python-single-r1
+
+DESCRIPTION="GNU Radio source block for OsmoSDR and rtlsdr and hackrf"
+HOMEPAGE="http://sdr.osmocom.org/trac/wiki/GrOsmoSDR"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/osmocom/gr-osmosdr.git"
+else
+	SRC_URI="https://github.com/osmocom/gr-osmosdr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+IUSE="airspy bladerf hackrf iqbalance mirisdr python rtlsdr sdrplay soapy uhd"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/boost:=
+	=net-wireless/gnuradio-3.8*:0=[${PYTHON_SINGLE_USEDEP}]
+	sci-libs/volk
+	airspy? ( net-wireless/airspy )
+	bladerf? ( >=net-wireless/bladerf-2018.08_rc1:= )
+	hackrf? ( net-libs/libhackrf:= )
+	iqbalance? ( net-wireless/gr-iqbal:=[${PYTHON_SINGLE_USEDEP}] )
+	mirisdr? ( net-libs/libmirisdr:= )
+	rtlsdr? ( >=net-wireless/rtl-sdr-0.5.4:= )
+	sdrplay? ( net-wireless/sdrplay )
+	soapy? ( net-wireless/soapysdr:= )
+	uhd? ( net-wireless/uhd:=[${PYTHON_SINGLE_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DEFAULT=OFF
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DENABLE_FILE=ON
+		-DENABLE_AIRSPY="$(usex airspy)"
+		-DENABLE_BLADERF="$(usex bladerf)"
+		-DENABLE_HACKRF="$(usex hackrf)"
+		-DENABLE_IQBALANCE="$(usex iqbalance)"
+		-DENABLE_MIRI="$(usex mirisdr)"
+		-DENABLE_PYTHON="$(usex python)"
+		-DENABLE_RTL="$(usex rtlsdr)"
+		-DENABLE_RTL_TCP="$(usex rtlsdr)"
+		-DENABLE_SOAPY="$(usex soapy)"
+		-DENABLE_UHD="$(usex uhd)"
+		-DENABLE_SDRPLAY="$(usex sdrplay)"
+		-DENABLE_NONFREE="$(usex sdrplay)"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	if use python; then
+		python_fix_shebang "${ED}"/usr/bin
+		python_optimize
+	fi
+	mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/doc/${P}"
+}