[gentoo-commits] repo/gentoo:master commit in: dev-python/oslo-i18n/

[Matt Thode]

commit:     500e451d755b9bcebef7bec4a32468b05ca180c3
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 16 04:56:43 2018 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Fri Feb 16 04:56:43 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=500e451d

dev-python/oslo-i18n: 3.19.0 bup

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 dev-python/oslo-i18n/Manifest                |  1 +
 dev-python/oslo-i18n/oslo-i18n-3.19.0.ebuild | 68 ++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-python/oslo-i18n/Manifest b/dev-python/oslo-i18n/Manifest
index 54cba0facd5..4cd436a0d68 100644
--- a/dev-python/oslo-i18n/Manifest
+++ b/dev-python/oslo-i18n/Manifest
@@ -1 +1,2 @@
 DIST oslo-i18n-3.17.1.tar.gz 42660 BLAKE2B 645a8341cf2bedf18932fbfa092b608da4169993a2a62aef36b869e975dfd662b7d52008aedf046b09ac10e4641e810902904b16e450a728b0f075fdee654977 SHA512 86d244eba7a887d4b8c3327487c9dd67c8e4baa52afdc05f94a229d6c1c951b8a25fc628f490320501773bb808afb8fb3b450a8d26e11b9a36a3c22baaa64544
+DIST oslo-i18n-3.19.0.tar.gz 41888 BLAKE2B 651b6e1ee2d2d6c11bd1b86b78eadf70b33338f5495fb93d58747635961df20fbf74fb2a949ef81b82efce582410f05c88806e678f688bb686b500378c77ff6e SHA512 2c12fc5ec24fbebd2624b3bf9d3043a62da84304e73a995c49b395e792bd9bd7d38a13f5e3086abe59bbb9ef43729a47eaee78ea0701ed05c15f5070af232a69

diff --git a/dev-python/oslo-i18n/oslo-i18n-3.19.0.ebuild b/dev-python/oslo-i18n/oslo-i18n-3.19.0.ebuild
new file mode 100644
index 00000000000..b5bcdc23765
--- /dev/null
+++ b/dev-python/oslo-i18n/oslo-i18n-3.19.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 vcs-snapshot
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Oslo i18n library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/coverage-4.0[${PYTHON_USEDEP}]
+		!~dev-python/coverage-4.4[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-5.1.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/openstackdocstheme-1.17.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+		>=dev-python/reno-2.5.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	!~dev-python/Babel-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPYTHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}