[gentoo-commits] gentoo-x86 commit in net-p2p/transmission: transmission-1.70.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    09/06/06 10:21:53

  Modified:             ChangeLog
  Added:                transmission-1.70.ebuild
  Log:
  Version bump. Use system libevent instead of bundled copy wrt #269082. Update init.d and conf.d files wrt #269655.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.83                 net-p2p/transmission/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	14 May 2009 18:40:04 -0000	1.82
+++ ChangeLog	6 Jun 2009 10:21:53 -0000	1.83
@@ -1,6 +1,14 @@
 # ChangeLog for net-p2p/transmission
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.82 2009/05/14 18:40:04 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.83 2009/06/06 10:21:53 ssuominen Exp $
+
+*transmission-1.70 (06 Jun 2009)
+
+  06 Jun 2009; Samuli Suominen <ssuominen@g.o>
+  +transmission-1.70.ebuild, +files/transmission-daemon.confd.1,
+  +files/transmission-daemon.initd.1:
+  Version bump. Use system libevent instead of bundled copy wrt #269082.
+  Update init.d and conf.d files wrt #269655.
 
   14 May 2009; Joseph Jezak <josejx@g.o> transmission-1.61.ebuild:
   Marked ppc stable for bug #269605.



1.1                  net-p2p/transmission/transmission-1.70.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/transmission-1.70.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/transmission-1.70.ebuild?rev=1.1&content-type=text/plain

Index: transmission-1.70.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-1.70.ebuild,v 1.1 2009/06/06 10:21:53 ssuominen Exp $

EAPI=2
inherit autotools fdo-mime gnome2-utils qt4

DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com"
SRC_URI="http://download.${PN}bt.com/${PN}/files/${P}.tar.bz2"

LICENSE="MIT GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="gtk libnotify qt4"

RDEPEND=">=dev-libs/libevent-1.4.11
	>=dev-libs/openssl-0.9.4
	|| ( >=net-misc/curl-7.16.3[ssl]
		>=net-misc/curl-7.16.3[gnutls] )
	gtk? ( >=dev-libs/glib-2.15.5:2
		>=x11-libs/gtk+-2.6:2
		>=dev-libs/dbus-glib-0.70
		libnotify? ( >=x11-libs/libnotify-0.4.3 ) )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/intltool
	dev-util/pkgconfig
	sys-apps/sed"

src_prepare() {
	sed -e 's:-g -O0::g' -e 's:-g -O3::g' -i configure.ac || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable gtk) \
		$(use_enable libnotify)

	if use qt4; then
		cd qt
		eqmake4 qtr.pro
	fi
}

src_compile() {
	emake || die "emake failed"

	if use qt4; then
		cd qt
		emake || die "emake failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS NEWS
	rm -f "${D}"/usr/share/${PN}/web/LICENSE

	newinitd "${FILESDIR}"/${PN}-daemon.initd.1 ${PN}-daemon
	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon

	if use qt4; then
		cd qt
		emake INSTALL_ROOT="${D}/usr" install || die "emake install failed"
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}