[gentoo-commits] gentoo-x86 commit in media-sound/rosegarden: ChangeLog rosegarden-13.10.ebuild

[Tim Harder (radhermit)]

radhermit    13/11/03 09:00:54

  Modified:             ChangeLog
  Added:                rosegarden-13.10.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.114                media-sound/rosegarden/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.114&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.114&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/ChangeLog?r1=1.113&r2=1.114

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v
retrieving revision 1.113
retrieving revision 1.114
diff -u -r1.113 -r1.114
--- ChangeLog	23 Jul 2013 05:16:37 -0000	1.113
+++ ChangeLog	3 Nov 2013 09:00:54 -0000	1.114
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/rosegarden
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.113 2013/07/23 05:16:37 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.114 2013/11/03 09:00:54 radhermit Exp $
+
+*rosegarden-13.10 (03 Nov 2013)
+
+  03 Nov 2013; Tim Harder <radhermit@g.o> +rosegarden-13.10.ebuild:
+  Version bump.
 
 *rosegarden-13.06 (23 Jul 2013)
 



1.1                  media-sound/rosegarden/rosegarden-13.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/rosegarden-13.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/rosegarden-13.10.ebuild?rev=1.1&content-type=text/plain

Index: rosegarden-13.10.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/rosegarden-13.10.ebuild,v 1.1 2013/11/03 09:00:54 radhermit Exp $

EAPI=5
inherit autotools eutils fdo-mime gnome2-utils multilib

DESCRIPTION="MIDI and audio sequencer and notation editor"
HOMEPAGE="http://www.rosegardenmusic.com/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug lirc"

RDEPEND="dev-qt/qtgui:4
	media-libs/ladspa-sdk
	x11-libs/libSM
	media-sound/jack-audio-connection-kit
	media-libs/alsa-lib
	>=media-libs/dssi-1.0.0
	media-libs/liblo
	media-libs/liblrdf
	sci-libs/fftw:3.0
	media-libs/libsamplerate[sndfile]
	lirc? ( app-misc/lirc )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	x11-misc/makedepend"

src_prepare() {
	if ! use lirc; then
		sed -i \
			-e '/AC_CHECK_HEADER/s:lirc_client.h:dIsAbLe&:' \
			-e '/AC_CHECK_LIB/s:lirc_init:dIsAbLe&:' \
			configure.ac || die
	fi

	epatch "${FILESDIR}"/${PN}-12.12.25-debug.patch

	eautoreconf
}

src_configure() {
	export USER_CXXFLAGS="${CXXFLAGS}"

	econf \
		$(use_enable debug) \
		--with-qtdir=/usr \
		--with-qtlibdir=/usr/$(get_libdir)/qt4
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}