[gentoo-commits] gentoo-x86 commit in x11-misc/zim: ChangeLog zim-0.61.ebuild zim-0.57.ebuild zim-0.56.ebuild

[Jeroen Roovers (jer)]

jer         14/08/28 09:55:22

  Modified:             ChangeLog
  Added:                zim-0.61.ebuild
  Removed:              zim-0.57.ebuild zim-0.56.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.23                 x11-misc/zim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/zim/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	31 May 2013 15:22:57 -0000	1.22
+++ ChangeLog	28 Aug 2014 09:55:22 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/zim
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/ChangeLog,v 1.22 2013/05/31 15:22:57 xmw Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/ChangeLog,v 1.23 2014/08/28 09:55:22 jer Exp $
+
+*zim-0.61 (28 Aug 2014)
+
+  28 Aug 2014; Jeroen Roovers <jer@g.o> -zim-0.56.ebuild,
+  -zim-0.57.ebuild, +zim-0.61.ebuild, files/zim-0.60-remove-ubuntu-theme.patch:
+  Version bump.
 
 *zim-0.60 (31 May 2013)
 



1.1                  x11-misc/zim/zim-0.61.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/zim-0.61.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/zim-0.61.ebuild?rev=1.1&content-type=text/plain

Index: zim-0.61.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/zim-0.61.ebuild,v 1.1 2014/08/28 09:55:22 jer Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="sqlite"
DISTUTILS_SINGLE_IMPL=1

inherit distutils-r1 gnome2-utils fdo-mime virtualx

DESCRIPTION="A desktop wiki"
HOMEPAGE="http://zim-wiki.org/"
SRC_URI="http://zim-wiki.org/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND="dev-python/pygtk[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	x11-misc/xdg-utils
	test? (
		dev-vcs/bzr
		dev-vcs/git
		dev-vcs/mercurial )"

PATCHES=( "${FILESDIR}"/${PN}-0.60-remove-ubuntu-theme.patch )

python_prepare() {
	sed -i -e "s/'USER'/'LOGNAME'/g" zim/__init__.py zim/fs.py || die
	distutils-r1_python_prepare
}

python_test() {
	VIRTUALX_COMMAND="${PYTHON}" virtualmake test.py
}

python_install() {
	distutils-r1_python_install --skip-xdg-cmd
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	if ! has_version ${CATEGORY}/${PN}; then
		einfo "Please emerge these packages for additional functionality"
		einfo "    dev-lang/R"
		einfo "    dev-python/gtkspell-python"
		einfo "    dev-vcs/bzr"
		einfo "    gnome-extra/zeitgeist"
		einfo "    media-gfx/graphviz"
		einfo "    media-gfx/imagemagick"
		einfo "    media-gfx/scrot"
		einfo "    media-sound/lilypond"
		einfo "    sci-visualization/gnuplot"
		einfo "    virtual/latex-base app-text/dvipng"
	fi
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}