[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

[Sam James]

commit:     999312580e14a5b438641cc3be7df0d30518531d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 25 19:28:02 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Feb 25 19:29:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=99931258

dev-util/diffoscope: add 206

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-206.ebuild | 108 ++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index d27e25ec4e63..2b791bdc323e 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,4 @@
 DIST diffoscope-201.tar.gz 2705733 BLAKE2B 97f74633bd990408af9ba33feb38243da22253b1f1c49a23d11cf6cc16197b3a4fdb371f01f310a2a5ee782ae89209c2f80b0956d48b0a5c5308dd6f50aba86f SHA512 a221d656a49b77f08eb884acc8bbabd1e4469ff2411d47532c0326743653b43e45a60e5fb39d841c1b835d896dbe9d08032f51f295f5399af878be18305acd52
 DIST diffoscope-204.tar.gz 2706432 BLAKE2B 61dbabc3a1137b594c44854616589edd434f66cb4434da4d4b96bdfbfe6de4e3bb3425dbcf0e7659082b75dbd82b95bc01d1f580933bf89661adca4c321600d2 SHA512 776d9ff09b7dc8abe20ea6346840cd480f3fbe3c6525e650078a0a133041a621d58850fd923bc1ce59050a15f53e64d6796bfb4d7bb158ce50b746ee4c3058af
 DIST diffoscope-205.tar.gz 2706492 BLAKE2B efeeef0ee12f5813dfd7de6b2128b1e6e7ad3cb9fae758c5337ddb04e86ec24d26581ba051fa31a8e825c423076f609fa0acbb07c26f6f89ec763e9939fca0cd SHA512 6a8a665c477dafa98a876d08ed6e7bb1e0528ec32f1d14430d14ea5fd54c15ffab66feaca48ec4bc82cd1e4d60ba8b629f3e9f4ed70cfaaf7d8cf0386c791991
+DIST diffoscope-206.tar.gz 2707148 BLAKE2B 043af705ac87c3eb2b43070936197de8d10daf5658cbcc94ffc3b2320b3cee6d0459af72116d723df1391ee864e5f5df1fd7bcbc4f2e2b404fc01b9de6f64277 SHA512 4a73aee54fa6868b950f08c51f40efb659f6433edfcbfdfb0e293514140aed3475e6abcf883677bd598586f217850c0d6384c22d82ba5278b4552d9a38d3a814

diff --git a/dev-util/diffoscope/diffoscope-206.ebuild b/dev-util/diffoscope/diffoscope-206.ebuild
new file mode 100644
index 000000000000..46f6608598b5
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-206.ebuild
@@ -0,0 +1,108 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+)
+
+distutils_enable_tests pytest