[gentoo-commits] gentoo-x86 commit in sys-cluster/moosefs: moosefs-1.6.20-r2.ebuild ChangeLog moosefs-1.6.20-r1.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    11/08/02 08:47:32

  Modified:             ChangeLog
  Added:                moosefs-1.6.20-r2.ebuild
  Removed:              moosefs-1.6.20-r1.ebuild
  Log:
  Add mfs CGI server init script. drop old.
  
  (Portage version: 2.1.10.9/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  sys-cluster/moosefs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/moosefs/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	8 Jul 2011 15:29:35 -0000	1.2
+++ ChangeLog	2 Aug 2011 08:47:31 -0000	1.3
@@ -1,6 +1,13 @@
 # ChangeLog for sys-cluster/moosefs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/moosefs/ChangeLog,v 1.2 2011/07/08 15:29:35 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/moosefs/ChangeLog,v 1.3 2011/08/02 08:47:31 ultrabug Exp $
+
+*moosefs-1.6.20-r2 (02 Aug 2011)
+
+  02 Aug 2011; Ultrabug <ultrabug@g.o> -moosefs-1.6.20-r1.ebuild,
+  +moosefs-1.6.20-r2.ebuild, +files/mfscgiserver.confd,
+  +files/mfscgiserver.initd:
+  Add mfs CGI server init script. drop old.
 
 *moosefs-1.6.20-r1 (08 Jul 2011)
 



1.1                  sys-cluster/moosefs/moosefs-1.6.20-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/moosefs-1.6.20-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/moosefs-1.6.20-r2.ebuild?rev=1.1&content-type=text/plain

Index: moosefs-1.6.20-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/moosefs/moosefs-1.6.20-r2.ebuild,v 1.1 2011/08/02 08:47:31 ultrabug Exp $

EAPI=4

inherit eutils

MY_P="mfs-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="A filesystem for highly reliable petabyte storage"
HOMEPAGE="http://www.moosefs.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cgi +fuse static-libs"

RDEPEND="
	cgi? ( dev-lang/python )
	fuse? ( >=sys-fs/fuse-2.6 )"
DEPEND="${RDEPEND}"

pkg_setup() {
	enewgroup mfs
	enewuser mfs -1 -1 -1 mfs
}

src_prepare() {
	# rename dist config files
	sed -i 's@\.cfg\.dist@\.cfg@g' mfsdata/Makefile.in || die
}

src_configure() {
	local myopts=""
	use fuse || myopts="--disable-mfsmount"
	econf \
		--sysconfdir=/etc/mfs \
		--with-default-user=mfs \
		--with-default-group=mfs \
		$(use_enable cgi mfscgi) \
		$(use_enable cgi mfscgiserv) \
		$(use_enable static-libs static) \
		${myopts}
}

src_install() {
	emake DESTDIR="${D}" install

	newinitd "${FILESDIR}/mfs.initd" mfs
	newconfd "${FILESDIR}/mfs.confd" mfs
	if use cgi; then
		newinitd "${FILESDIR}/mfscgiserver.initd" mfscgiserver
		newconfd "${FILESDIR}/mfscgiserver.confd" mfscgiserver
	fi

	chown -R mfs:mfs "${D}/var/lib/mfs" || die
	chmod 750 "${D}/var/lib/mfs" || die
}