[gentoo-commits] gentoo-x86 commit in sys-boot/unetbootin: unetbootin-584.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         13/06/06 14:23:39

  Modified:             ChangeLog
  Added:                unetbootin-584.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.98                 sys-boot/unetbootin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?rev=1.98&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?rev=1.98&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?r1=1.97&r2=1.98

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v
retrieving revision 1.97
retrieving revision 1.98
diff -u -r1.97 -r1.98
--- ChangeLog	2 Mar 2013 23:34:41 -0000	1.97
+++ ChangeLog	6 Jun 2013 14:23:39 -0000	1.98
@@ -1,6 +1,11 @@
 # ChangeLog for sys-boot/unetbootin
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.97 2013/03/02 23:34:41 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.98 2013/06/06 14:23:39 jer Exp $
+
+*unetbootin-584 (06 Jun 2013)
+
+  06 Jun 2013; Jeroen Roovers <jer@g.o> +unetbootin-584.ebuild:
+  Version bump.
 
   02 Mar 2013; Markos Chandras <hwoarang@g.o> unetbootin-583.ebuild:
   Move Qt dependencies to the new category



1.1                  sys-boot/unetbootin/unetbootin-584.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/unetbootin-584.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/unetbootin-584.ebuild?rev=1.1&content-type=text/plain

Index: unetbootin-584.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/unetbootin-584.ebuild,v 1.1 2013/06/06 14:23:39 jer Exp $

EAPI=5

inherit eutils qt4-r2

DESCRIPTION="Universal Netboot Installer creates Live USB systems for various OS
distributions."
HOMEPAGE="http://unetbootin.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-source-${PV}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE=""

UNBI_LINGUAS="
	am ar ast be bg bn ca cs da de el eo es et eu fa fi fo fr gl he hr hu id it
	ja lt lv ml ms nan nb nl nn pl pt_BR pt ro ru si sk sl sr sv sw tr uk ur vi
	zh_CN zh_TW
"

for lingua in ${UNBI_LINGUAS}; do
	IUSE="${IUSE} linguas_${lingua}"
done

S="${WORKDIR}"

DEPEND="dev-qt/qtgui:4"
RDEPEND="${DEPEND}
		 sys-fs/mtools
		 sys-boot/syslinux
		 app-arch/p7zip"

src_prepare() {
	epatch "${FILESDIR}/${PN}-581-desktop.patch"

	# QA check in case linguas are added or removed
	enum() {
		echo ${#}
	}
	[[ $(enum ${UNBI_LINGUAS}) -eq $(( $(enum $(echo ${PN}_*.ts) ) -1 )) ]] \
		|| die "Numbers of recorded and actual linguas do not match"
	unset enum

	# Make room between the last line of TRANSLATIONS and the next definition
	sed -i \
		-e '/^DEFINES/s|.*|\n&|g' \
		${PN}.pro || die

	# Remove localisations
	local lingua
	for lingua in ${UNBI_LINGUAS}; do
		if ! use linguas_${lingua}; then
			sed -i ${PN}.pro -e "/\.*${PN}_${lingua}\.ts.*/d" || die
			rm ${PN}_${lingua}.ts || die
		fi
	done
}

src_configure() {
	lupdate ${PN}.pro || die
	lrelease ${PN}.pro || die
	eqmake4 ${PN}.pro || die
}

src_install() {
	dobin ${PN}

	domenu ${PN}.desktop

	for file in ${PN}*.png; do
		size="${file/${PN}_}"
		size="${size/.png}x${size/.png}"
		insinto /usr/share/icons/hicolor/${size}/apps
		newins ${file} ${PN}.png
	done

	local lingua
	for lingua in ${UNBI_LINGUAS}; do
		if use linguas_${lingua}; then
			insinto /usr/share/${PN}
			doins ${PN}_${lingua}.qm
		fi
	done
}