[gentoo-commits] gentoo-x86 commit in app-office/kmymoney: ChangeLog kmymoney-4.5.2.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    11/01/03 12:26:35

  Modified:             ChangeLog
  Added:                kmymoney-4.5.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.9.26/cvs/Linux i686)

Revision  Changes    Path
1.15                 app-office/kmymoney/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/kmymoney/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/kmymoney/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/kmymoney/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/kmymoney/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	11 Nov 2010 23:54:50 -0000	1.14
+++ ChangeLog	3 Jan 2011 12:26:35 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/kmymoney
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/kmymoney/ChangeLog,v 1.14 2010/11/11 23:54:50 dilfridge Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/kmymoney/ChangeLog,v 1.15 2011/01/03 12:26:35 dilfridge Exp $
+
+*kmymoney-4.5.2 (03 Jan 2011)
+
+  03 Jan 2011; Andreas K. Huettel <dilfridge@g.o>
+  +kmymoney-4.5.2.ebuild:
+  Version bump
 
 *kmymoney-4.5-r2 (11 Nov 2010)
 



1.1                  app-office/kmymoney/kmymoney-4.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/kmymoney/kmymoney-4.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/kmymoney/kmymoney-4.5.2.ebuild?rev=1.1&content-type=text/plain

Index: kmymoney-4.5.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/kmymoney/kmymoney-4.5.2.ebuild,v 1.1 2011/01/03 12:26:35 dilfridge Exp $

EAPI=3

KMNAME="extragear/office"

if [[ ${PV} != *9999* ]]; then
	KDE_LINGUAS="bg ca ca@valencia cs da de el en_GB eo es et fi fr ga gl hu it lt
	ms nds nl pl pt pt_BR ro ru sk sv tr uk zh_CN zh_TW"
	KDE_DOC_DIRS="doc doc-translations/%lingua_${PN}"
	KDE_HANDBOOK="optional"
	SRC_URI="mirror://sourceforge/kmymoney2/${P}.tar.bz2
		mirror://gentoo/${P}-aqbanking-5_x.patch.bz2"
fi

inherit virtualx kde4-base

DESCRIPTION="A personal finance manager for KDE"
HOMEPAGE="http://kmymoney2.sourceforge.net/"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="debug calendar doc hbci ofx quotes test"

COMMON_DEPEND="
	app-crypt/gpgme
	>=dev-libs/boost-1.33.1
	dev-libs/libgpg-error
	dev-libs/libxml2
	$(add_kdebase_dep kdepimlibs)
	calendar? ( dev-libs/libical )
	hbci? (
		>=net-libs/aqbanking-5.0.1
		>=sys-libs/gwenhywfar-4.0.1[qt4]
	)
	ofx? ( >=dev-libs/libofx-0.9.1 )
"
RDEPEND="${COMMON_DEPEND}
	quotes? ( >=dev-perl/Finance-Quote-1.17 )
"
DEPEND="${COMMON_DEPEND}
	doc? ( app-doc/doxygen )
	test? ( >=dev-util/cppunit-1.12.1 )
"

PATCHES=( "${WORKDIR}/${P}"-aqbanking-5_x.patch )

src_configure() {
	mycmakeargs=(
		-DUSE_QT_DESIGNER=OFF
		$(cmake-utils_use_enable calendar LIBICAL)
		$(cmake-utils_use_use doc DEVELOPER_DOC)
		$(cmake-utils_use_enable hbci KBANKING)
		$(cmake-utils_use_enable ofx LIBOFX)
		$(cmake-utils_use test KDE4_BUILD_TESTS)
	)
	kde4-base_src_configure
}

src_compile() {
	kde4-base_src_compile
	use doc && kde4-base_src_compile apidoc
}

src_install() {
	use doc && HTML_DOCS=("${CMAKE_BUILD_DIR}/apidocs/html/")
	kde4-base_src_install
}

src_test() {
	export maketype="kde4-base_src_test"
	virtualmake
}