[gentoo-commits] gentoo-x86 commit in dev-util/dialog: ChangeLog dialog-1.1.20111020.ebuild

[Jeroen Roovers (jer)]

jer         11/12/27 03:19:51

  Modified:             ChangeLog
  Added:                dialog-1.1.20111020.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha83/cvs/Linux x86_64)

Revision  Changes    Path
1.140                dev-util/dialog/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.140&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.140&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?r1=1.139&r2=1.140

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v
retrieving revision 1.139
retrieving revision 1.140
diff -u -r1.139 -r1.140
--- ChangeLog	10 Dec 2011 02:35:59 -0000	1.139
+++ ChangeLog	27 Dec 2011 03:19:51 -0000	1.140
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/dialog
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.139 2011/12/10 02:35:59 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.140 2011/12/27 03:19:51 jer Exp $
+
+*dialog-1.1.20111020 (27 Dec 2011)
+
+  27 Dec 2011; Jeroen Roovers <jer@g.o> +dialog-1.1.20111020.ebuild:
+  Version bump.
 
   10 Dec 2011; Naohiro Aota <naota@g.o> dialog-1.1.20110707-r1.ebuild:
   Does work with <FreeBSD-9; Add block. Bug #352455



1.1                  dev-util/dialog/dialog-1.1.20111020.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.1.20111020.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.1.20111020.ebuild?rev=1.1&content-type=text/plain

Index: dialog-1.1.20111020.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/dialog-1.1.20111020.ebuild,v 1.1 2011/12/27 03:19:51 jer Exp $

EAPI="2"

inherit multilib

MY_PV="${PV/1.1./1.1-}"
S=${WORKDIR}/${PN}-${MY_PV}
DESCRIPTION="tool to display dialog boxes from a shell"
HOMEPAGE="http://invisible-island.net/dialog/dialog.html"
SRC_URI="ftp://invisible-island.net/${PN}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="examples minimal nls static-libs unicode"

RDEPEND="
	>=app-shells/bash-2.04-r3
	!unicode? ( >=sys-libs/ncurses-5.2-r5 )
	unicode? ( >=sys-libs/ncurses-5.2-r5[unicode] )
"
DEPEND="
	${RDEPEND}
	nls? ( sys-devel/gettext )
	!minimal? ( sys-devel/libtool )
	!<=sys-freebsd/freebsd-contrib-8.9999
"

src_prepare() {
	sed -i configure -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' || die
}

src_configure() {
	local ncursesw
	use unicode && ncursesw="w"
	econf \
		$(use_enable nls) \
		$(use_with !minimal libtool) \
		--with-ncurses${ncursesw}
}

src_install() {
	if use minimal; then
		emake DESTDIR="${D}" install || die "install failed"
	else
		emake DESTDIR="${D}" install-full || die "install failed"
	fi

	dodoc CHANGES README VERSION

	if use examples; then
		docinto samples
		dodoc samples/*
	fi

	if ! use static-libs; then
		rm -f \
			"${D}"usr/$(get_libdir)/libdialog.a \
			"${D}"usr/$(get_libdir)/libdialog.la
	fi
}