[gentoo-commits] repo/gentoo:master commit in: net-mail/onionrouter/

[Craig Andrews]

commit:     ac1936e82ef20aa73d9ecd7bcb56f7f3ce0cb287
Author:     Craig Andrews <candrews <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 28 18:32:22 2020 +0000
Commit:     Craig Andrews <candrews <AT> gentoo <DOT> org>
CommitDate: Wed Oct 28 18:32:40 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ac1936e8

net-mail/onionrouter: Add live version

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Craig Andrews <candrews <AT> gentoo.org>

 net-mail/onionrouter/onionrouter-9999.ebuild | 53 ++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/net-mail/onionrouter/onionrouter-9999.ebuild b/net-mail/onionrouter/onionrouter-9999.ebuild
new file mode 100644
index 00000000000..35d74e96b3d
--- /dev/null
+++ b/net-mail/onionrouter/onionrouter-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 systemd
+
+DESCRIPTION=".onion discovery via SRV DNS lookups for use with postfix"
+HOMEPAGE="https://pypi.org/project/onionrouter/ https://github.com/ehloonion/onionrouter/"
+if [[ ${PV} == *9999 ]] ; then
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/ehloonion/onionrouter.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://pypi.io/packages/source/${PN::1}/${PN}/${P}.tar.gz"
+fi
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="$(python_gen_cond_dep '
+	dev-python/dnspython[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+')"
+BDEPEND="$(python_gen_cond_dep '
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)
+')"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# https://github.com/ehloonion/onionrouter/pull/15
+	cp "${FILESDIR}/conftest.py" "${S}" || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	insinto /etc/onionrouter
+	doins "${S}/onionrouter/configs/onionrouter.ini"
+}