[gentoo-commits] gentoo-x86 commit in app-editors/gedit: ChangeLog gedit-3.12.2-r1.ebuild gedit-3.12.1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    14/09/29 14:31:01

  Modified:             ChangeLog
  Added:                gedit-3.12.2-r1.ebuild
  Removed:              gedit-3.12.1.ebuild
  Log:
  Really allow multiple python targets for python plugins and install gi overrides in the right place (bug #524018, thanks to Alexander Tsoy). Drop old.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

Revision  Changes    Path
1.372                app-editors/gedit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.372&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.372&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/gedit/ChangeLog?r1=1.371&r2=1.372

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v
retrieving revision 1.371
retrieving revision 1.372
diff -u -r1.371 -r1.372
--- ChangeLog	23 Jul 2014 15:13:11 -0000	1.371
+++ ChangeLog	29 Sep 2014 14:31:01 -0000	1.372
@@ -1,6 +1,14 @@
 # ChangeLog for app-editors/gedit
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.371 2014/07/23 15:13:11 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.372 2014/09/29 14:31:01 tetromino Exp $
+
+*gedit-3.12.2-r1 (29 Sep 2014)
+
+  29 Sep 2014; Alexandre Rostovtsev <tetromino@g.o>
+  -gedit-3.12.1.ebuild, +gedit-3.12.2-r1.ebuild:
+  Really allow multiple python targets for python plugins and install gi
+  overrides in the right place (bug #524018, thanks to Alexander Tsoy). Drop
+  old.
 
   23 Jul 2014; Agostino Sarubbo <ago@g.o> gedit-3.12.2.ebuild:
   Stable for x86, wrt bug #512012



1.1                  app-editors/gedit/gedit-3.12.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/gedit/gedit-3.12.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/gedit/gedit-3.12.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: gedit-3.12.2-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-3.12.2-r1.ebuild,v 1.1 2014/09/29 14:31:01 tetromino Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes" # plugins are dlopened
PYTHON_COMPAT=( python3_{2,3} )

inherit eutils gnome2 multilib python-r1 virtualx

DESCRIPTION="A text editor for the GNOME desktop"
HOMEPAGE="https://wiki.gnome.org/Apps/Gedit"

LICENSE="GPL-2+ CC-BY-SA-3.0"
SLOT="0"

IUSE="+introspection +python spell zeitgeist"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"

# X libs are not needed for OSX (aqua)
COMMON_DEPEND="
	>=dev-libs/libxml2-2.5.0:2
	>=dev-libs/glib-2.39.5:2
	>=x11-libs/gtk+-3.11.6:3[introspection?]
	>=x11-libs/gtksourceview-3.11.2:3.0[introspection?]
	>=dev-libs/libpeas-1.7.0[gtk]

	gnome-base/gsettings-desktop-schemas
	gnome-base/gvfs

	x11-libs/libX11

	net-libs/libsoup:2.4

	introspection? ( >=dev-libs/gobject-introspection-0.9.3 )
	python? (
		${PYTHON_DEPS}
		>=dev-libs/gobject-introspection-0.9.3
		>=x11-libs/gtk+-3:3[introspection]
		>=x11-libs/gtksourceview-3.6:3.0[introspection]
		dev-python/pycairo[${PYTHON_USEDEP}]
		>=dev-python/pygobject-3:3[cairo,${PYTHON_USEDEP}] )
	spell? (
		>=app-text/enchant-1.2:=
		>=app-text/iso-codes-0.35 )
	zeitgeist? ( >=gnome-extra/zeitgeist-0.9.12 )
"
RDEPEND="${COMMON_DEPEND}
	x11-themes/gnome-icon-theme-symbolic
	python? ( dev-libs/libpeas[${PYTHON_USEDEP}] )
"
DEPEND="${COMMON_DEPEND}
	app-text/docbook-xml-dtd:4.1.2
	>=app-text/scrollkeeper-0.3.11
	dev-libs/libxml2:2
	>=dev-util/gtk-doc-am-1
	>=dev-util/intltool-0.50.1
	>=sys-devel/gettext-0.18
	virtual/pkgconfig
"
# yelp-tools, gnome-common needed to eautoreconf

src_prepare() {
	# FIXME: Not able to set some metadata
	sed -e '/g_test_add_func/d' \
		-i tests/document-loader.c || die

	gnome2_src_prepare
}

src_configure() {
	DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"

	gedit_configure() {
		ECONF_SOURCE=${S} \
		gnome2_src_configure \
			--disable-deprecations \
			--enable-updater \
			--enable-gvfs-metadata \
			$(use_enable introspection) \
			$(use_enable spell) \
			$(use_enable zeitgeist) \
			ITSTOOL=$(type -P true) \
			"$@"
	}

	gedit_py_configure() {
		mkdir -p "${BUILD_DIR}" || die
		run_in_build_dir gedit_configure --enable-python
	}

	# run gedit_py_configure first to avoid out-of-source build for C code
	use python && python_parallel_foreach_impl gedit_py_configure
	gedit_configure --disable-python
}

src_test() {
	# FIXME: this should be handled at eclass level
	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die

	unset DBUS_SESSION_BUS_ADDRESS
	GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
}

src_install() {
	gedit_py_install() {
		pushd "${BUILD_DIR}" > /dev/null || die
		# manually set pyoverridesdir due to bug #524018 and AM_PATH_PYTHON limitations
		emake DESTDIR="${D}" top_builddir="${S}" pyoverridesdir="$(python_get_sitedir)/gi/overrides" install
		popd > /dev/null
	}

	gnome2_src_install
	use python && python_foreach_impl gedit_py_install
}