[gentoo-commits] gentoo-x86 commit in media-libs/libjpeg-turbo: ChangeLog libjpeg-turbo-1.1.90_p20120129.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/01/28 21:29:43

  Modified:             ChangeLog
  Added:                libjpeg-turbo-1.1.90_p20120129.ebuild
  Log:
  New snapshot to resolve rendering problems wrt #401233 by Alec M.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 media-libs/libjpeg-turbo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	27 Jan 2012 23:42:11 -0000	1.24
+++ ChangeLog	28 Jan 2012 21:29:42 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libjpeg-turbo
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog,v 1.24 2012/01/27 23:42:11 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog,v 1.25 2012/01/28 21:29:42 ssuominen Exp $
+
+*libjpeg-turbo-1.1.90_p20120129 (29 Jan 2012)
+
+  29 Jan 2012; Samuli Suominen <ssuominen@g.o>
+  +libjpeg-turbo-1.1.90_p20120129.ebuild:
+  New snapshot to resolve rendering problems wrt #401233 by Alec M.
 
   27 Jan 2012; Samuli Suominen <ssuominen@g.o>
   libjpeg-turbo-1.1.90_p20120128.ebuild:



1.1                  media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90_p20120129.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90_p20120129.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90_p20120129.ebuild?rev=1.1&content-type=text/plain

Index: libjpeg-turbo-1.1.90_p20120129.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90_p20120129.ebuild,v 1.1 2012/01/28 21:29:43 ssuominen Exp $

# http://libjpeg-turbo.svn.sourceforge.net/viewvc/libjpeg-turbo/branches/1.2.x/?view=tar

EAPI=4

unset _inherits

JPEG_ABI=8

if [[ ${PV} == *_p20* ]]; then
	SRC_URI="http://dev.gentoo.org/~ssuominen/${P}.tar.xz"
	_inherits=autotools
else
	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
fi

inherit ${_inherits} java-pkg-opt-2 libtool toolchain-funcs

DESCRIPTION="MMX, SSE, and SSE2 SIMD accelerated JPEG library"
HOMEPAGE="http://libjpeg-turbo.virtualgl.org/ http://sourceforge.net/projects/libjpeg-turbo/"
SRC_URI="${SRC_URI}
	mirror://debian/pool/main/libj/libjpeg${JPEG_ABI}/libjpeg${JPEG_ABI}_${JPEG_ABI}c-2.debian.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="java static-libs"

ASM_DEPEND="|| ( dev-lang/nasm dev-lang/yasm )"
COMMON_DEPEND="!media-libs/jpeg:0"
RDEPEND="${COMMON_DEPEND}
	java? ( >=virtual/jre-1.5 )"
DEPEND="${COMMON_DEPEND}
	amd64? ( ${ASM_DEPEND} )
	x86? ( ${ASM_DEPEND} )
	amd64-linux? ( ${ASM_DEPEND} )
	x86-linux? ( ${ASM_DEPEND} )
	java? ( >=virtual/jdk-1.5 )"

DOCS="*.txt change.log example.c README"

src_prepare() {
	if [[ -x ./configure ]]; then
		elibtoolize
	else
		eautoreconf
	fi
	java-pkg-opt-2_src_prepare
}

src_configure() {
	if use java; then
		export JAVACFLAGS="$(java-pkg_javac-args)"
		export JNI_CFLAGS="$(java-pkg_get-jni-cflags)"
	fi

	econf \
		$(use_enable static-libs static) \
		--with-jpeg${JPEG_ABI} \
		$(use_with java)
}

src_compile() {
	local _java_makeopts
	use java && _java_makeopts="-j1"
	emake ${_java_makeopts}

	ebegin "Building exifautotran and jpegexiforient extra tools"
	pushd ../debian/extra >/dev/null
	emake CC="$(tc-getCC)" CFLAGS="${LDFLAGS} ${CFLAGS}"
	popd >/dev/null
	eend $?
}

src_test() {
	emake test
}

src_install() {
	default
	find "${ED}"usr -name '*.la' -exec rm -f {} +

	insinto /usr/share/doc/${PF}/html
	doins -r doc/html/*

	if use java; then
		insinto /usr/share/doc/${PF}/html/java
		doins -r java/doc/*
		newdoc java/README README.java

		rm -rf "${ED}"usr/classes
		java-pkg_dojar java/turbojpeg.jar
	fi

	ebegin "Installing exifautotran and jpegexiforient extra tools"
	pushd ../debian/extra >/dev/null
	newdoc ../changelog changelog.debian

	emake \
		DESTDIR="${D}" prefix="${EPREFIX}"/usr \
		INSTALL="install -m755" INSTALLDIR="install -d -m755" \
		install
	popd >/dev/null
	eend $?
}