[gentoo-commits] gentoo-x86 commit in www-misc/zoneminder: ChangeLog zoneminder-1.24.2.ebuild

[Thomas Anderson (gentoofan23)]

gentoofan23    09/08/03 11:19:59

  Modified:             ChangeLog
  Added:                zoneminder-1.24.2.ebuild
  Log:
  Add www-misc/zoneminder-1.24.2; fixes bug #262019 and security bug #236517.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.36                 www-misc/zoneminder/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-misc/zoneminder/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-misc/zoneminder/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-misc/zoneminder/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-misc/zoneminder/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	16 Jul 2009 08:59:19 -0000	1.35
+++ ChangeLog	3 Aug 2009 11:19:59 -0000	1.36
@@ -1,6 +1,16 @@
 # ChangeLog for www-misc/zoneminder
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-misc/zoneminder/ChangeLog,v 1.35 2009/07/16 08:59:19 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-misc/zoneminder/ChangeLog,v 1.36 2009/08/03 11:19:59 gentoofan23 Exp $
+
+*zoneminder-1.24.2 (03 Aug 2009)
+
+  03 Aug 2009; Thomas Anderson <gentoofan23@g.o>
+  +files/1.24.2/Makefile.am.patch, +zoneminder-1.24.2.ebuild,
+  +files/1.24.2/db_upgrade_script_location.patch,
+  +files/1.24.2/zm_create.sql.in.patch,
+  +files/1.24.2/zm_remote_camera_http.patch:
+  Add www-misc/zoneminder-1.24.2; fixes bug #262019 and security bug
+  #236517.
 
   16 Jul 2009; Torsten Veller <tove@g.o> zoneminder-1.23.3.ebuild,
   metadata.xml:



1.1                  www-misc/zoneminder/zoneminder-1.24.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-misc/zoneminder/zoneminder-1.24.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-misc/zoneminder/zoneminder-1.24.2.ebuild?rev=1.1&content-type=text/plain

Index: zoneminder-1.24.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-misc/zoneminder/zoneminder-1.24.2.ebuild,v 1.1 2009/08/03 11:19:59 gentoofan23 Exp $

inherit eutils autotools depend.php depend.apache multilib

MY_PV=${PV/_/-}
MY_PN="ZoneMinder"

PATCH_PV="1.24.2"

DESCRIPTION="ZoneMinder allows you to capture, analyse, record and monitor any cameras attached to your system."
HOMEPAGE="http://www.zoneminder.com/"
SRC_URI="http://www.zoneminder.com/downloads/${MY_PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug ffmpeg"
#IUSE="debug ffmpeg mmap"
SLOT="0"

DEPEND="app-admin/sudo
	dev-libs/libpcre
	>=media-libs/jpeg-6b
	net-libs/gnutls
	>=dev-lang/perl-5.6.0
	virtual/perl-Archive-Tar
	dev-perl/Archive-Zip
	dev-perl/DateManip
	dev-perl/DBD-mysql
	dev-perl/DBI
	dev-perl/Device-SerialPort
	dev-perl/libwww-perl
	dev-perl/MIME-Lite
	dev-perl/MIME-tools
	dev-perl/PHP-Serialization
	virtual/perl-Getopt-Long
	virtual/perl-libnet
	virtual/perl-Module-Load
	virtual/perl-Sys-Syslog
	virtual/perl-Time-HiRes"

RDEPEND="dev-perl/DBD-mysql
	ffmpeg? ( >=media-video/ffmpeg-0.5-r1 )
	media-libs/netpbm"

# we cannot use need_httpd_cgi here, since we need to setup permissions for the
# webserver in global scope (/etc/zm.conf etc), so we hardcode apache here.
need_apache
need_php_httpd

S="${WORKDIR}"/${MY_PN}-${MY_PV}

pkg_setup() {
	require_php_with_use mysql sockets apache2
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${PATCH_PV}/Makefile.am.patch
	epatch "${FILESDIR}"/${PATCH_PV}/zm_create.sql.in.patch
	epatch "${FILESDIR}"/${PATCH_PV}/zm_remote_camera_http.patch
	epatch "${FILESDIR}"/${PATCH_PV}/db_upgrade_script_location.patch

	eautoreconf
}

src_compile() {
	local myconf

# To enable mmap support we need a dependancy of Sys::Mmap
# It installs fine via g-cpan, but there's no ebuild currently in portage.
#	if use mmap; then
#		myconf="${myconf} --enable-mmap=yes"
#	else
#		myconf="${myconf} --enable-mmap=no"
#	fi

	if use debug; then
		myconf="${myconf} --enable-debug=yes --enable-crashtrace=yes"
	else
		myconf="${myconf} --enable-debug=no --enable-crashtrace=no"
	fi

	econf   --with-libarch=$(get_libdir) \
		--with-mysql=/usr \
		$(use_with ffmpeg) \
		--with-webdir="${ROOT}var/www/zoneminder/htdocs" \
		--with-cgidir="${ROOT}var/www/zoneminder/cgi-bin" \
		--with-webuser=apache \
		--with-webgroup=apache \
		${myconf}

	einfo "${PN} does not parallel build... using forcing make -j1..."
	emake -j1 || die "emake failed"
}

src_install() {
	keepdir /var/run/zm
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	fperms 0640 /etc/zm.conf

	keepdir /var/log/${PN}
	fowners apache:apache /var/log/${PN}
	fowners apache:apache /var/run/zm

	newinitd "${FILESDIR}"/init.d zoneminder
	newconfd "${FILESDIR}"/conf.d zoneminder

	dodoc AUTHORS ChangeLog INSTALL NEWS README TODO

	insinto /usr/share/${PN}/db
	doins db/zm_u* db/zm_create.sql

	insinto /etc/apache2/vhosts.d
	doins "${FILESDIR}"/10_zoneminder.conf

	for DIR in events images sound; do
		dodir "${ROOT}"/var/www/zoneminder/htdocs/${DIR}
	done
}

pkg_postinst() {
	elog ""
	elog "0. If this is a new installation, you will need to create a MySQL database"
	elog "   for ${PN} to use. (see http://www.gentoo.org/doc/en/mysql-howto.xml)."
	elog "   Once you completed that you should execute the following:"
	elog ""
	elog " cd /usr/share/${PN}"
	elog " mysql -u <my_database_user> -p<my_database_pass> <my_zoneminder_db> < db/zm_create.sql"
	elog ""
	elog "1.  Set your database settings in /etc/zm.conf"
	elog ""
	elog "2.  Start the ${PN} daemon:"
	elog ""
	elog "  /etc/init.d/${PN} start"
	elog ""
	elog "3. Finally point your browser to http://localhost/${PN}"
	elog ""
	elog ""
	elog "If you are upgrading, you will need to run the zmupdate.pl script:"
	elog ""
	elog " /usr/bin/zmupdate.pl version=<from version> [--user=<my_database_user> --pass=<my_database_pass>]"
	elog ""
}