[gentoo-commits] gentoo-x86 commit in net-irc/znc: ChangeLog znc-0.206.ebuild

[Justin Lecher (jlec)]

jlec        12/05/29 17:49:40

  Modified:             ChangeLog
  Added:                znc-0.206.ebuild
  Log:
  Non maintainer Version BUmp
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.59                 net-irc/znc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	3 May 2012 06:27:13 -0000	1.58
+++ ChangeLog	29 May 2012 17:49:40 -0000	1.59
@@ -1,6 +1,11 @@
 # ChangeLog for net-irc/znc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v 1.58 2012/05/03 06:27:13 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v 1.59 2012/05/29 17:49:40 jlec Exp $
+
+*znc-0.206 (29 May 2012)
+
+  29 May 2012; Justin Lecher <jlec@g.o> +znc-0.206.ebuild:
+  Non maintainer Version BUmp
 
   03 May 2012; Jeff Horelick <jdhore@g.o> znc-0.094.ebuild,
   znc-0.202-r1.ebuild, znc-0.204.ebuild, znc-9999.ebuild:



1.1                  net-irc/znc/znc-0.206.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/znc-0.206.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/znc/znc-0.206.ebuild?rev=1.1&content-type=text/plain

Index: znc-0.206.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/znc-0.206.ebuild,v 1.1 2012/05/29 17:49:40 jlec Exp $

EAPI=4

PYTHON_DEPEND="python? 3"
inherit base python

DESCRIPTION="An advanced IRC Bouncer"
HOMEPAGE="http://znc.sourceforge.net"
SRC_URI="http://znc.in/releases/archive/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="ares debug extras ipv6 perl python ssl sasl tcl"

RDEPEND="
	ares? ( >=net-dns/c-ares-1.5 )
	perl? ( >=dev-lang/perl-5.10 )
	sasl? ( >=dev-libs/cyrus-sasl-2 )
	ssl? ( >=dev-libs/openssl-0.9.7d )
	tcl? ( dev-lang/tcl )
"
DEPEND="
	virtual/pkgconfig
	perl? ( dev-lang/swig )
	python? (
		>=dev-lang/swig-2.0.2
		>=dev-lang/perl-5.10
	)
	${RDEPEND}
"

pkg_setup() {
	if use python; then
		python_set_active_version 3
		python_pkg_setup
	fi
}

src_configure() {
	econf \
		$(use_enable ares c-ares) \
		$(use_enable debug) \
		$(use_enable extras extra) \
		$(use_enable ipv6) \
		$(use_enable perl) \
		$(use python && echo "--enable-python=python-$(python_get_version)") \
		$(use_enable sasl) \
		$(use_enable ssl openssl) \
		$(use_enable tcl tcl)
}

src_install() {
	emake install DESTDIR="${D}"
	dodoc AUTHORS README.md
}

pkg_postinst() {
	elog
	elog "Run 'znc --makeconf' as the user you want to run ZNC as"
	elog "to make a configuration file"
	elog "If you are using SSL you should also run 'znc --makepem'"
	elog
}