[gentoo-commits] repo/gentoo:master commit in: sci-libs/libsc/

[Matthias Maier]

commit:     ec9971f53e8494a72310820ff95732712ef4f472
Author:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
AuthorDate: Fri May 26 16:32:55 2017 +0000
Commit:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Fri May 26 17:11:40 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec9971f5

sci-libs/libsc: Initial commit, move from science overlay

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 sci-libs/libsc/Manifest          |  2 +
 sci-libs/libsc/libsc-1.0.ebuild  | 68 ++++++++++++++++++++++++++++++
 sci-libs/libsc/libsc-1.1.ebuild  | 70 +++++++++++++++++++++++++++++++
 sci-libs/libsc/libsc-9999.ebuild | 90 ++++++++++++++++++++++++++++++++++++++++
 sci-libs/libsc/metadata.xml      | 22 ++++++++++
 5 files changed, 252 insertions(+)

diff --git a/sci-libs/libsc/Manifest b/sci-libs/libsc/Manifest
new file mode 100644
index 00000000000..475f0dc527b
--- /dev/null
+++ b/sci-libs/libsc/Manifest
@@ -0,0 +1,2 @@
+DIST libsc-1.0.tar.gz 257930 SHA256 a9f8a0f342a4a92c4031735e044e7ee73d9fd7e6df3e50a51c4c5016e27ed1ba SHA512 bf5af600e9cbd4038b1bd40c88776b21be5d474e34f9aacf287b890d262a22dc50ca27982c2eb9adba9735c8d9bb1fc31de2a27b24cdab534e3b2f610d76db7d WHIRLPOOL 56f89fcaf90bc8d4f872cee4fe150f692933b39376758c42b67d2e42659c19a9332a1d5e6d2d81c011dade0c6ab40c526c69ce2168fe41060f5d4be1a6595b1b
+DIST libsc-1.1.tar.gz 263643 SHA256 99c3fb3b7d6514ccaa667bdc848a7308c00f05bf6fdc0561ce286db9644ee03e SHA512 a3d8bea406a1987e68e88dd587aebe28c796f2a5bddfc381b34b5eb1448e0ac23889cc6f97fc1e4010289f83996180db42cbb001d0518360349b993dd37d4579 WHIRLPOOL b6c123cd245e4beb4cd6479e9d781d86784fab6975edc20562c14b5ecc59dbc824aca10fb02e4fa7612f0b2743fd7c7d3799f203546c5859896812a21e1362df

diff --git a/sci-libs/libsc/libsc-1.0.ebuild b/sci-libs/libsc/libsc-1.0.ebuild
new file mode 100644
index 00000000000..f20b97e1195
--- /dev/null
+++ b/sci-libs/libsc/libsc-1.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils
+
+DESCRIPTION="Support for parallel scientific applications"
+HOMEPAGE="http://www.p4est.org/"
+SRC_URI="https://github.com/cburstedde/libsc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug examples mpi romio static-libs"
+
+REQUIRED_USE="romio? ( mpi )"
+
+RDEPEND="
+	dev-lang/lua:*
+	sys-apps/util-linux
+	virtual/blas
+	virtual/lapack
+	mpi? ( virtual/mpi[romio?] )"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README )
+
+src_prepare() {
+	default
+
+	# Inject a version number into the build system
+	echo "${PV}" > ${S}/.tarball-version
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable mpi)
+		$(use_enable romio mpiio)
+		$(use_enable static-libs static)
+		--with-blas="$($(tc-getPKG_CONFIG) --libs blas)"
+		--with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		docinto examples
+		dodoc -r example/*
+		docompress -x /usr/share/doc/${PF}/examples
+	else
+		# Remove compiled example binaries in case of -examples:
+		rm -r "${ED}"/usr/bin || die "rm failed"
+	fi
+
+	# Fix wrong installation paths:
+	dodir /usr/share/libsc
+	mv "${ED}"/etc/* "${ED}"/usr/share/libsc || die "mv failed"
+	rmdir "${ED}"/etc/ || die "rmdir failed"
+}

diff --git a/sci-libs/libsc/libsc-1.1.ebuild b/sci-libs/libsc/libsc-1.1.ebuild
new file mode 100644
index 00000000000..58390d3dedd
--- /dev/null
+++ b/sci-libs/libsc/libsc-1.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils
+
+DESCRIPTION="Support for parallel scientific applications"
+HOMEPAGE="http://www.p4est.org/"
+SRC_URI="https://github.com/cburstedde/libsc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug examples mpi romio static-libs"
+
+REQUIRED_USE="romio? ( mpi )"
+
+RDEPEND="
+	dev-lang/lua:*
+	sys-apps/util-linux
+	virtual/blas
+	virtual/lapack
+	mpi? ( virtual/mpi[romio?] )"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README )
+
+AUTOTOOLS_AUTORECONF=true
+
+src_prepare() {
+	default
+
+	# Inject a version number into the build system
+	echo "${PV}" > ${S}/.tarball-version
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable mpi)
+		$(use_enable romio mpiio)
+		$(use_enable static-libs static)
+		--with-blas="$($(tc-getPKG_CONFIG) --libs blas)"
+		--with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		docinto examples
+		dodoc -r example/*
+		docompress -x /usr/share/doc/${PF}/examples
+	else
+		# Remove compiled example binaries in case of -examples:
+		rm -r "${ED}"/usr/bin || die "rm failed"
+	fi
+
+	# Fix wrong installation paths:
+	dodir /usr/share/libsc
+	mv "${ED}"/etc/* "${ED}"/usr/share/libsc || die "mv failed"
+	rmdir "${ED}"/etc/ || die "rmdir failed"
+}

diff --git a/sci-libs/libsc/libsc-9999.ebuild b/sci-libs/libsc/libsc-9999.ebuild
new file mode 100644
index 00000000000..b6090443790
--- /dev/null
+++ b/sci-libs/libsc/libsc-9999.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools toolchain-funcs eutils
+
+DESCRIPTION="Support for parallel scientific applications"
+HOMEPAGE="http://www.p4est.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://github.com/cburstedde/libsc.git"
+	EGIT_BRANCH="develop"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/cburstedde/libsc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="debug examples mpi openmp romio static-libs threads"
+
+REQUIRED_USE="romio? ( mpi )"
+
+RDEPEND="
+	dev-lang/lua:*
+	sys-apps/util-linux
+	virtual/blas
+	virtual/lapack
+	mpi? ( virtual/mpi[romio?] )"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README )
+
+AUTOTOOLS_AUTORECONF=true
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != "binary" ]] && use openmp; then
+		tc-has-openmp || \
+			die "Please select an openmp capable compiler like gcc[openmp]"
+	fi
+}
+
+src_prepare() {
+	default
+
+	# Inject a version number into the build system
+	echo "${PV}" > ${S}/.tarball-version
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable mpi)
+		$(use_enable openmp openmp)
+		$(use_enable romio mpiio)
+		$(use_enable static-libs static)
+		$(use_enable threads pthread)
+		--with-blas="$($(tc-getPKG_CONFIG) --libs blas)"
+		--with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		docinto examples
+		dodoc -r example/*
+		docompress -x /usr/share/doc/${PF}/examples
+	else
+		# Remove compiled example binaries in case of -examples:
+		rm -r "${ED}"/usr/bin || die "rm failed"
+	fi
+
+	# Fix wrong installation paths:
+	dodir /usr/share/libsc
+	mv "${ED}"/etc/* "${ED}"/usr/share/libsc || die "mv failed"
+	rmdir "${ED}"/etc/ || die "rmdir failed"
+	mv "${ED}"/usr/share/ini/* "${ED}"/usr/share/libsc || die "mv failed"
+	rmdir "${ED}"/usr/share/ini || die "rmdir failed"
+}

diff --git a/sci-libs/libsc/metadata.xml b/sci-libs/libsc/metadata.xml
new file mode 100644
index 00000000000..18bfaa1e547
--- /dev/null
+++ b/sci-libs/libsc/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>tamiko@g.o</email>
+		<name>Matthias Maier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>sci@g.o</email>
+		<name>Gentoo Science Project</name>
+	</maintainer>
+	<longdescription lang="en">
+The SC Library provides support for parallel scientific applications.
+This support library is primarily used by sci-libs/p4est.
+	</longdescription>
+	<use>
+		<flag name="romio">Build with support for the ROMIO MPI-IO component</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">cburstedde/libsc</remote-id>
+	</upstream>
+</pkgmetadata>