[gentoo-commits] repo/gentoo:master commit in: dev-python/python-neutronclient/

[Matt Thode]

commit:     7dbf373d5ca15a5bf6dbda5d70fd6d562147c11c
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 27 05:00:10 2017 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Mon Feb 27 05:45:26 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7dbf373d

dev-python/python-neutronclient: bup

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 dev-python/python-neutronclient/Manifest           |  1 +
 .../python-neutronclient-6.1.0.ebuild              | 95 ++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/dev-python/python-neutronclient/Manifest b/dev-python/python-neutronclient/Manifest
index 7ff13cb2ab..1aeda83375 100644
--- a/dev-python/python-neutronclient/Manifest
+++ b/dev-python/python-neutronclient/Manifest
@@ -1,2 +1,3 @@
 DIST python-neutronclient-4.1.1.tar.gz 187794 SHA256 4d5c60358272174afb019d68940f67ddad09367b2e6210e3206d19566777c293 SHA512 654a7e8d98b1b6c3fbd1a183196982ea8bb9a0a97707e7a4ddb4cde47a97e93c3356961193c305b3ab33cb8ee2273b1a941c2655e1f56a3e2a8131deaed54922 WHIRLPOOL ead87cb41f57f285a03583ca91e843a0f9c4edaefaa7020d38c949dbd56d46611f44e36c087a9684d2e87c0d236ff8124022b2afacd9b8438b6b8b6716ec9c81
 DIST python-neutronclient-6.0.0.tar.gz 205872 SHA256 a30556f8b9541e94f44a9911d9af89037710761755758a2c1598fa92809293a2 SHA512 eb9a71fee8e551d4436236bbb93ea03496f6094b6b444a1624a98bc85c26122b5bbe3a935fbc8a1f921b6449a481deaba284645ca62c56e3771d57bf526c6d8a WHIRLPOOL 966ced0e9f195b2e71cf7944f3eeb699ef59c7ca7a4df4cb2835dbb1d7f8c47f4483ea51deb974b56c43ceec8b52f92778d56f7d89aec3d0c5fee74b1dc13048
+DIST python-neutronclient-6.1.0.tar.gz 229036 SHA256 b6b68e6a3bd4945f9ececf730a88cebde73c5edfd88588a335ea871af872faed SHA512 12d1c1ab1e50852f9b7db0591208cc46fa830bf7747cd7b5f67914ffa1c5822e600a6932b213e297ec6fdd068beb9e1b0abace627f0388091f7b4c649a7032a4 WHIRLPOOL 78ed52ecef306ca0a896e9c10968fa423c7b71cc7691fad88ef01be9da6ca72f419ac7534083109951951a6246c888c806beb54185e4e15da2dfae0f1157f491

diff --git a/dev-python/python-neutronclient/python-neutronclient-6.1.0.ebuild b/dev-python/python-neutronclient/python-neutronclient-6.1.0.ebuild
new file mode 100644
index 0000000000..a671ec84e7
--- /dev/null
+++ b/dev-python/python-neutronclient/python-neutronclient-6.1.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="https://launchpad.net/neutron"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+REQUIRED_USE="test? ( doc )"
+
+CDEPEND=">=dev-python/pbr-1.6[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/coverage-4.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mox3-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/python-openstackclient-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/reno-1.8.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.4[${PYTHON_USEDEP}]
+	)"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/cliff-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.13[${PYTHON_USEDEP}]
+	!~dev-python/netaddr-0.7.16[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/os-client-config-1.22.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-2.17.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.10.0[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.12.2[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# built in...
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && "${PYTHON}" setup.py build_sphinx
+}
+
+python_test() {
+	testr init
+	testr run || die "tests failed under python2.7"
+	flake8 neutronclient/tests || die "run by flake8 over tests folder yielded error"
+}
+
+python_install() {
+	distutils-r1_python_install
+	#stupid stupid
+	local SITEDIR="${D%/}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.egg-info )
+	#[[ -f ${egg[0]} ]] || die "python_quantumclient*.egg-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}