[gentoo-commits] repo/gentoo:master commit in: dev-qt/qtcore/

[Andreas Sturmlechner]

commit:     f9447476d1a2484ec8da6c19f9f91dad84d3b699
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  8 14:16:05 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Feb  8 21:34:22 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f9447476

dev-qt/qtcore: Drop vulnerable 5.12.3-r1

Bug: https://bugs.gentoo.org/707354
Package-Manager: Portage-2.3.87, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-qt/qtcore/qtcore-5.12.3-r1.ebuild | 86 -----------------------------------
 1 file changed, 86 deletions(-)

diff --git a/dev-qt/qtcore/qtcore-5.12.3-r1.ebuild b/dev-qt/qtcore/qtcore-5.12.3-r1.ebuild
deleted file mode 100644
index 8fa01e2779f..00000000000
--- a/dev-qt/qtcore/qtcore-5.12.3-r1.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-QT5_MODULE="qtbase"
-inherit qt5-build
-
-DESCRIPTION="Cross-platform application development framework"
-
-if [[ ${QT5_BUILD_TYPE} == release ]]; then
-	KEYWORDS="arm x86"
-fi
-
-IUSE="icu systemd"
-
-DEPEND="
-	dev-libs/double-conversion:=
-	dev-libs/glib:2
-	dev-libs/libpcre2[pcre16,unicode]
-	sys-libs/zlib:=
-	icu? ( dev-libs/icu:= )
-	!icu? ( virtual/libiconv )
-	systemd? ( sys-apps/systemd:= )
-"
-RDEPEND="${DEPEND}
-	!<dev-qt/qtcore-4.8.7-r4:4
-"
-
-QT5_TARGET_SUBDIRS=(
-	src/tools/bootstrap
-	src/tools/moc
-	src/tools/rcc
-	src/tools/qfloat16-tables
-	src/corelib
-	src/tools/qlalr
-	doc
-)
-
-QT5_GENTOO_PRIVATE_CONFIG=(
-	!:network
-	!:sql
-	!:testlib
-	!:xml
-)
-
-PATCHES=( "${FILESDIR}/${P}-CVE-2019-18281.patch" )
-
-src_prepare() {
-	# don't add -O3 to CXXFLAGS, bug 549140
-	sed -i -e '/CONFIG\s*+=/s/optimize_full//' src/corelib/corelib.pro || die
-
-	# fix missing qt_version_tag symbol w/ LTO, bug 674382
-	sed -i -e 's/^gcc:ltcg/gcc/' src/corelib/global/global.pri || die
-
-	qt5-build_src_prepare
-}
-
-src_configure() {
-	local myconf=(
-		-no-feature-statx	# bug 672856
-		$(qt_use icu)
-		$(qt_use !icu iconv)
-		$(qt_use systemd journald)
-	)
-	qt5-build_src_configure
-}
-
-src_install() {
-	qt5-build_src_install
-
-	local flags=(
-		DBUS FREETYPE IMAGEFORMAT_JPEG IMAGEFORMAT_PNG
-		OPENGL OPENSSL SSL WIDGETS
-	)
-
-	for flag in ${flags[@]}; do
-		cat >> "${D%/}"/${QT5_HEADERDIR}/QtCore/qconfig.h <<- _EOF_ || die
-
-			#if defined(QT_NO_${flag}) && defined(QT_${flag})
-			# undef QT_NO_${flag}
-			#elif !defined(QT_NO_${flag}) && !defined(QT_${flag})
-			# define QT_NO_${flag}
-			#endif
-		_EOF_
-	done
-}