[gentoo-commits] gentoo-x86 commit in app-admin/system-config-printer-common: metadata.xml ChangeLog system-config-printer-common-1.1.8.ebuild

[Alex Alexander (wired)]

wired       09/08/04 11:39:42

  Added:                metadata.xml ChangeLog
                        system-config-printer-common-1.1.8.ebuild
  Log:
  new ebuild from kde-testing overlay
  (Portage version: 2.2_rc35/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-admin/system-config-printer-common/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/system-config-printer-common/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/system-config-printer-common/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>kde</herd>
</pkgmetadata>



1.1                  app-admin/system-config-printer-common/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-admin/system-config-printer-common
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.1 2009/08/04 11:39:42 wired Exp $

*system-config-printer-common-1.1.8 (04 Aug 2009)

  04 Aug 2009; Alex Alexander <wired@g.o>
  +system-config-printer-common-1.1.8.ebuild,
  +files/system-config-printer-common-1.1.8-split.patch, +metadata.xml:
  new ebuild from kde-testing overlay




1.1                  app-admin/system-config-printer-common/system-config-printer-common-1.1.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.1.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.1.8.ebuild?rev=1.1&content-type=text/plain

Index: system-config-printer-common-1.1.8.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.1.8.ebuild,v 1.1 2009/08/04 11:39:42 wired Exp $

EAPI="2"
inherit python autotools

MY_P="${PN%-common}-${PV}"

DESCRIPTION="Common modules of Red Hat's printer administration tool"
HOMEPAGE="http://cyberelk.net/tim/software/system-config-printer/"
SRC_URI="http://cyberelk.net/tim/data/system-config-printer/1.1/${MY_P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="doc"

# system-config-printer split since 1.1.3
DEPEND="
	doc? ( dev-python/epydoc )
"
RDEPEND="
	!app-admin/system-config-printer:0
	dev-libs/libxml2[python]
	dev-python/dbus-python
	dev-python/pycups
	dev-python/pygobject
	net-print/cups[dbus]
"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}/${P}-split.patch"

	eaclocal
	eautomake
	eautoconf
}

src_configure() {
	econf --disable-nls
}

src_compile() {
	emake || die "emake failed"
	if 	use doc; then
		emake html || die "emake html failed"
	fi
}

src_install() {
	dodoc AUTHORS ChangeLog README || die "dodoc failed"

	if use doc; then
		dohtml -r html/ || die "installing html docs failed"
	fi

	emake DESTDIR="${D}" install || die "emake install failed"
}